如何在电子邮件中填充.BCC 字段？

Question

I am trying, in MS Access 2013, to grab email addresses from a query pointing to a table and populate the .BCC field in an Outlook email.

I can populate the .To field with email addresses using .recipients.add .

How can I do the same thing in the .BCC field?
I tried dozens of examples and the closest I got is populating the last email address from the table.

Private Sub Command180_Click()
    Dim rs As DAO.Recordset
    Dim OlApp As Object
    Dim OlMail As Object
    Dim strEmail As String
                 
    Set OlApp = CreateObject("Outlook.Application")
    Set OutMail = OlApp.CreateItem(olMailItem)
                
    Set rs = CurrentDb.OpenRecordset("SELECT POCEmail FROM qDistroActiveEmails")
    With rs
        Do Until .EOF
            strEmail = !PocEmail
        
            With OutMail
                .BCC = strEmail
                .Recipients.Add strEmail
            End With

            rs.MoveNext
        Loop
    End With
    rs.Close
    Set rs = Nothing
    
    OutMail.Display

End Sub

Answer 1

Recipients.Add returns a Recipient object (which your code ignores). Set it's Type property to olBCC (3)

Dim recip as Object
...
With OutMail
  set recip = .Recipients.Add(strEmail)
  recip.Type = 3
End With

Answer 2

The BCC property accepts a string of semi-colon-separated email addresses. Also note that this code adds emails to recipients and BCC, which means they will receive duplicate emails. If you want them to be blind copied only, don't add them to Recipients.

Use this instead:

Private Sub Command180_Click()
    Dim rs As DAO.Recordset
    Dim OlApp As Object
    Dim OutMail As Object
    Dim strEmail As String
    Dim bccEmails As String

    Set OlApp = CreateObject("Outlook.Application")
    Set OutMail = OlApp.CreateItem(olMailItem)

    Set rs = CurrentDb.OpenRecordset("SELECT Email FROM Emails")
    With rs
        Do Until .EOF
            strEmail = !Email
            ' add email to BCC email list string
            bccEmails = bccEmails & strEmail & ";"

            With OutMail
                .Recipients.Add strEmail
            End With

            rs.MoveNext
        Loop
    End With
    rs.Close
    Set rs = Nothing

    ' set BCC using string of concatenated emails                  
    OutMail.BCC = left(bccEmails, Len(bccEmails) - 1) ' trims trailing semicolon

    OutMail.Display

End Sub