运行宏后，如何按升序排序此Excel列中的金额？

Question

I can't get the values I enter into column D to be sorted by ascending order.

 Sheets("Template").Select
    Range("A2").Select
    Range(Selection, ActiveCell.SpecialCells(xlLastCell)).Select
    Selection.Copy
    Sheets("OutPut").Select
    Range("A1").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False
    Application.CutCopyMode = False
    Selection.Sort Key1:=Range("D1"), Order1:=xlAscending, Header:=xlYes, _
        OrderCustom:=1, MatchCase:=False, Orientation:=xlTopToBottom, _
        DataOption1:=xlSortTextAsNumbers```

Answer 1

Perhaps like this?

Sub tgr()

    Dim wb As Workbook
    Dim wsTemplate As Worksheet
    Dim wsOutput As Worksheet
    Dim rCopy As Range

    Set wb = ActiveWorkbook
    Set wsTemplate = wb.Worksheets("Template")
    Set wsOutput = wb.Worksheets("OutPut")

    Set rCopy = wsTemplate.Range("A2", wsTemplate.Cells.SpecialCells(xlCellTypeLastCell))
    With wsOutput.Range("A1").Resize(rCopy.Rows.Count, rCopy.Columns.Count)
        .Value = rCopy.Value
        .Sort Intersect(.Cells, .Parent.Columns("D")), xlAscending, Header:=xlYes, OrderCustom:=1, DataOption1:=xlSortTextAsNumbers
    End With

End Sub