一起使用INNER JOIN和插入和更新时在VB.Net中出错

Question

I'm trying to INSERT and UPDATE using INNER JOIN but whenever I save it gives me an error around SET I can't figure it out what it is really wrong with it it's my first time using INNER JOIN I really need help for this

mysqlConn.Open()
sqlCmd = New Odbc.OdbcCommand
sqlCmd.Connection = mysqlConn

sqlCmd.CommandText = "INSERT INTO customer (guestno, datein, dateout, fullname, address, contactnum, total, paid, balance) VALUES ('" & Replace(Trim(staff_ri_txtguestno.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_dtpin.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_dtpout.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_txtfullname.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_txtaddress.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_txtnumber.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_txttotal.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_txtpaid.Text), "'", "''") & "', '" & Replace(Trim(staff_ri_txtbalance.Text), "'", "''") & "')
SET room.customer_id = customer.customer_id
UPDATE room SET roomstatus = '" & Replace(Trim("Occupied"), "'", "''") & "'
FROM room T1 INNER Join customer T2 ON T1.customer_id = T2.customer_id
WHERE room_id ='" & staff_lblid.Text & "'"
dr = sqlCmd.ExecuteReader

mysqlConn.Close()

My database structure

Table name: room

room_id | roomnum | roomstatus | roomtype | rate | customer_id

Table name: customer

customer_id | guestno | datein | dateout | fullname | address | contactnum | total | paid | balance

Here's the error Screenshot

Answer 1

Breaking down your code and Sql statement, what you are asking MySql to do is:

1. INSERT new customer ... - This looks OK
2. SET Customer Id on the Room table ... - This is not valid Sql
3. UPDATE Room status ... - This looks OK.

Couple this with how your generating your Sql statements it is understandable that you are having issues.

What I did was to rewrite your Sql using Parameters, which will help prevent many issues now and in the future, and also break down the changes to the Customer and Room tables in to two separate Sql statements that are executed at the same time.

Using conn As New MySqlConnection(ConnectionString)
    Dim insertCustomerSql As String = String.Empty
    insertCustomerSql += "INSERT INTO CUSTOMER (guestno, datein, dateout, name, address, contactnum, total, paid, balance) "
    insertCustomerSql += "VALUES (@guestNo, @dateIn, @dateOut, @name, @address, @contactNum, @total, @paid, @balance);"

    Dim updateRoomSql As String = String.Empty
    updateRoomSql += "UPDATE ROOM SET roomstatus = @roomStatus, customerid = LAST_INSERT_ID() WHERE id = @roomId;"

    Dim sql As String = insertCustomerSql + Environment.NewLine + updateRoomSql

    conn.Open()

    Using command As New MySqlCommand(sql, conn)
        command.Parameters.Add("guestNo", MySqlDbType.String).Value = 101
        command.Parameters.Add("dateIn", MySqlDbType.Date).Value = DateTime.Now.Date
        command.Parameters.Add("dateOut", MySqlDbType.Date).Value = DateTime.Now.Date.AddDays(5)
        command.Parameters.Add("name", MySqlDbType.String).Value = "JayV"
        command.Parameters.Add("address", MySqlDbType.String).Value = "My Home, England"
        command.Parameters.Add("contactNum", MySqlDbType.String).Value = "+44 1234 5678"
        command.Parameters.Add("total", MySqlDbType.Decimal).Value = 500
        command.Parameters.Add("paid", MySqlDbType.Decimal).Value = 350
        command.Parameters.Add("balance", MySqlDbType.Decimal).Value = 150

        command.Parameters.Add("roomStatus", MySqlDbType.String).Value = "Occupied"
        command.Parameters.Add("roomId", MySqlDbType.Int16).Value = 1
        command.ExecuteNonQuery()
    End Using
End Using

I also took the opportunity to make use of some other good practices, like the Using blocks.

Hope this helps you.