Delphi将对象作为单击事件的参数传递

Question

I have this code:

for LSidebarButton in SidebarButtons do
  begin
    LSidebarOverlay := TPanel(LSidebarButton.Button.Controls[3]);
    LSidebarOverlay.OnClick := SetSidebarButtonActive(nil, LSidebarButton);
  end;

And then I have a procedure

procedure SetSidebarButtonActive(sender: TObject; btn: TSidebarButton);
begin
    btn.SetActive;
    //more code
end;

And I'm getting this error:

E2010 Incompatible types: 'TNotifyEvent' and 'procedure, untyped pointer or untyped parameter'

Answer 1

The error is because you are trying to call SetSidebarButtonActive() and then assign its result (which it has none) to the OnClick event. That will not work.

The OnClick event is defined as a TNotifyEvent :

TNotifyEvent = procedure(Sender: TObject) of object;

That means that

• the procedure needs to be a member of a class

• you have to assign the address of the procedure to OnClick , not call the procedure

• the procedure must take only 1 input parameter, which is the TObject that fires the event (in this case, the TPanel that is being clicked on).

So, for what you are attempting, you would need to do something more like this instead:

procedure TMyForm.DoSomething;
var
  ...
  LSidebarButton: TSidebarButton;
  LSidebarOverlay: TPanel;
  ...
begin
  ...
  for LSidebarButton in SidebarButtons do
  begin
    LSidebarOverlay := TPanel(LSidebarButton.Button.Controls[3]);
    LSidebarOverlay.OnClick := SetSidebarButtonActive;
  end;
  ...
end;

procedure TMyForm.SetSidebarButtonActive(Sender: TObject);
var
  Pnl: TPanel;
  Btn: TSidebarButton;
begin
  Pnl := TPanel(Sender);

  Btn := (Pnl.Parent as TSidebarButton);
  // or maybe (Pnl.Parent.Parent as TSidebarButton)?
  // or maybe (Pnl.Owner as TSidebarButton)?
  // or maybe (Pnl.Parent.Owner as TSidebarButton)?
  // Hard to know with your example. Use whatever you
  // need to get back to the TSidebarButton from its
  // inner child TPanel...

  Btn.SetActive;
  ...
end;

Alternatively, you can store the TSidebarButton reference in the TPanel.Tag property (assuming you are not using it for something else):

procedure TMyForm.DoSomething;
var
  ...
  LSidebarButton: TSidebarButton;
  LSidebarOverlay: TPanel;
  ...
begin
  ...
  for LSidebarButton in SidebarButtons do
  begin
    LSidebarOverlay := TPanel(LSidebarButton.Button.Controls[3]);
    LSidebarOverlay.Tag := NativeInt(LSidebarButton);
    LSidebarOverlay.OnClick := SetSidebarButtonActive;
  end;
  ...
end;

procedure TMyForm.SetSidebarButtonActive(Sender: TObject);
var
  Btn: TSidebarButton;
begin
  Btn := TSidebarButton(TPanel(Sender).Tag);
  Btn.SetActive;
  ...
end;

Alternatively, you can define a helper class to provide you access to the TSidebarButton without looking at the TPanel at all:

type
  TOverlayClickHelper = class(TComponent)
  public
    Button: TSidebarButton;
    procedure OnClick(Sender: TObject);
  end;

...

procedure SetSidebarButtonActive(Btn: TSidebarButton);
begin
  Btn.SetActive;
  //more code
end;

procedure TOverlayClickHelper.OnClick(Sender: TObject);
begin
  SetSidebarButtonActive(Button);
end;

procedure TMyForm.DoSomething;
var
  ...
  LSidebarButton: TSidebarButton;
  LSidebarOverlay: TPanel;
  Helper: TOverlayClickHelper;
  ...
begin
  ...
  for LSidebarButton in SidebarButtons do
  begin
    LSidebarOverlay := TPanel(LSidebarButton.Button.Controls[3]);
    Helper := TOverlayClickHelper(LSidebarOverlay.FindComponent('MyHelper'));
    if Helper = nil then
    begin
      Helper := TOverlayClickHelper.Create(LSidebarOverlay);
      Helper.Name := 'MyHelper';
    end;
    Helper.Button := LSidebarButton;
    LSidebarOverlay.OnClick := Helper.OnClick;
  end;
  ...
end;

Alternatively, if you are creating the TPanel objects yourself inside of TSidebarButton , you could simply derive a new class from TPanel to add a TSidebarButton reference to it:

type
  TSidebarButtonPanel = class(TPanel)
  public
    Button: TSidebarButton;
  end;

...

procedure TSidebarButton.CreateOverlay;
var
  LOverlay: TSidebarButtonPanel;
begin
  LOverlay := TSidebarButtonPanel.Create(Self);
  LOverlay.Parent := Self.Button;
  LOverlay.Button := Self;
  ...
end;

...

procedure TMyForm.DoSomething;
var
  ...
  LSidebarButton: TSidebarButton;
  LSidebarOverlay: TPanel;
  ...
begin
  ...
  for LSidebarButton in SidebarButtons do
  begin
    LSidebarOverlay := TPanel(LSidebarButton.Button.Controls[3]);
    LSidebarOverlay.OnClick := SetSidebarButtonActive;
  end;
  ...
end;

procedure TMyForm.SetSidebarButtonActive(Sender: TObject);
var
  Btn: TSidebarButton;
begin
  Btn := TSidebarButtonPanel(Sender).Button;
  Btn.SetActive;
  ...
end;

There are all kinds of options available to you.