如何使用SAS中包含一个值的另一个数据集为新变量分配值

Question

I have a dataframe

ID value1
1   12
2   345
3   342

i have a second dataframe

value2
3823

how do I get the following result?

ID value1 value2
1   12     3823
2   345    3823
3   342    3823

any joins I have done have given me

ID value1 value2
1   12       .
2   345      .
3   342      .
.    .      3823

Answer 1

No need for joins or helper variables:

data have;
do i = 1 to 3;
  output;
end;
run;

data lookup;
  j = 1;
run;

data want;
  set have; 
  if _n_ = 1 then set lookup;
run;

Without the if _n_ = 1 , the data step stops after one iteration when it tries to read a second row from the lookup dataset and finds that there are no rows remaining.

NB this requires that the have dataset doesn't already contain a variable with the same name as the variable(s) attached from the lookup dataset.

Answer 2

By far the easiest way to do this is to utilize PROC SQL and defining the condition 1=1, which is always true for each comparison:

data first; 
    input ID value1 @@;
    cards; 
    1   12 2   345 3   342
run;

data second;
    input value2 ; 
    cards;
    3823
run;

proc sql; 
    create table wanted as 
    select * from first
    left join second 
    on 1 =1
;quit;

Edit: As far as I know, there isn't direct way to merge datasets by each row, but you can do the following trick:

Add variable Help:

data second_trick; 
set second; 
    help=1; 
run;
data first_trick; 
    set first; 
    help=1; 
run;

Then we just perform the merge by the static variable:

data wanted_trick; 
    merge first_trick(in=a) second_trick; 
    by help; 
    if a; /*Left join, just to be sure.*/
run;

now this only works if you want to add single static value. Don't try to use it your Second set has more rows.

For more on Merges and joins see: https://support.sas.com/resources/papers/proceedings/proceedings/sugi30/249-30.pdf