根据TODAY（）函数和每月的第一天移动范围

Question

I have a range which starts with =EDATE($A$46,-5) where A46 is =TODAY() . This range extends 5 additional cells to the right, with each cell containing =EDATE(_cell to the left_,1) and formatted to show just the month. This way, I end up with a complete range from left to right that shows the previous 6 months (ie. January, February, March, April, May, June). On the first of the month, the range obviously changes to include the current new month, and the prior 5 months behind it.

In each of the cells below the months, I have data (entered manually) containing amounts for an account. On the first of each month, when the workbook is opened, I need to cut the data that is in the data cells and move it back one column to account for the new additional month that is added (because the earliest month is now gone and hence so should the data be gone).

So from the picture above, you can see that on July 1, I will want to move the February, March, April, May, and June data one column to the left (because January will be gone at that point). I'd obviously need this to be dynamic so it occurs on the first of each month.

Sorry that I don't have any code here but I didn't even know where to start to do something based on the first of each month. The workbook is currently macro enabled and does have a macro attached to it.

Answer 1

First you need a characteristic sign to recognize the new month.
This could be the day's number, but the first might be on a weekend - so we need a better solution.

I suggest to insert the headlines not by formula, but initially manual as date (still as full date, shown as monthname only). Then VBA code can compare the last cell's text with the current month's name.

If you place this code in the workbook's module, it runs on every opening of the file. It copies the range including headlines, inserts the new date in the last headline and clears the content below it.

I assumed the range shown in your image is A47 to F51.
Please adapt it and the sheet's name to your needs.

Private Sub Workbook_Open()
    Dim CurrentMonthname As String
    Dim MsgAnswer As Integer

    CurrentMonthname = MonthName(Month(Date), False) ' or Format(Date, "MMMM")
    With Me.Sheets("AccountAmount")
        If .Range("F47").Text <> CurrentMonthname Then
            If MsgBox("Insert new month and move data?", _
              vbQuestion + vbOKCancel, "New Month") = vbOK Then
                .Range("A47:E51").Value = .Range("B47:F51").Value
                .Range("F47").Value = Date
                .Range("F48:F51").ClearContents
            End If
        End If
    End With
End Sub