如何使用MailMerge字段作为删除Word中的一行表的条件？ 需要VBA代码

Question

Creating a bill/letter:

This is a Excel-to-Word-bill-creation attempt to automatize work process.

I have used MailMerge to add fields from Excel to Word tables. I have 3 separate tables in Word, each with different number of rows. In rows 1 to n-1, there are 4 columns, and in the nth row there are 2 columns. I would like to use macro to delete:

1. whole table, if a cell(n,2) value is 0 ("n" - last row of the table, "0" - MailMerge field of value "0.00").
2. a row, if a cell(i,4) value is 0 (1 < "i" < n, "0" - MailMerge field of value "0.00").

    Sub DeleteEmptyTablerowsandcolumns()
        Application.ScreenUpdating = False
        Dim Tbl As Table, cel As Cell, i As Long, n As Long
        With ActiveDocument
            For Each Tbl In .Tables
                n = Tbl.Rows.Count
                m = Tbl.Range.Rows(n).Cells.Count
                If (Tbl.Cell(n, 2).Range.Text = "0.00") Then
                    Tbl.Delete
                    Selection.TypeBackspace
                Else: For i = n - 1 To 2 Step -1
                        If Len(Tbl.Cell(i, 4).Range.Text) <= 2 Then
                            Tbl.Rows(i).Delete
                        End If

                      Next i
                End If
            Next Tbl
        End With
        Application.ScreenUpdating = True
        End Sub

Right now, I cannot target cell values with MailMerge fields, for the code to work. The whole code would be a great thing to get. I assume solution is trivial, but still out of the reach. Thanks in advance!

Answer 1

You infer that you're using mailmerge but, if that is so, there will be no mergefields in the output once the merge has completed. The fact you're still finding mergefields therefore suggests you're at most doing a mailmerge preview. Try the following, which completes the merge then does the necessary processing. You can either run the code manually as you've apparently been doing, or by choosing Finish and Merge>Edit Individual Documents.

Sub MailMergeToDoc()
Application.ScreenUpdating = False
Dim Tbl As Table, r As Long
ActiveDocument.MailMerge.Execute
For Each Tbl In ActiveDocument.Tables
  With Tbl
    If Split(.Range.Cells(.Range.Cells.Count).Range, vbCr)(0) = "0.00" Then
      .Delete
    Else
      For r = .Rows.Count - 1 To 2 Step -1
        If Split(.Cell(r, 4).Range.Text, vbCr)(0) = "0.00" Then .Rows(r).Delete
      Next r
    End If
  End With
Next Tbl
Application.ScreenUpdating = True
End Sub

As coded, the macro assumes the cells to be tested contain "0.00"; if that's not what they contain post-merge, edit the code accordingly.