如何从Perl中的数组引用中优雅地创建哈希？

Question

I am looking for a more elegant way to create a hash that contains the list I have read in from my configuration file. Here is my code:

read_config($config_file => my %config);

my $extension_list_reference = $config{extensions}{ext};

my @ext;

# Store each item of the list into an array

for my $i ( 0 .. (@$extension_list_reference - 1) ) {
    $ext[$i] = $extension_list_reference->[$i];
}

# Create hash with the array elements as the keys

foreach my $entry (@ext) {
    $extensions{$entry} = "include";
 }   

Thanks.

Answer 1

my %hash = map { $_ => 'include' } @list;

Answer 2

Try using map: http://perldoc.perl.org/functions/map.html

Here's what your new code should look like:

my %extensions = map { $_ => "include" } @{ $config{extensions}{ext} };

Answer 3

If I understand your problem, this is how you do it in one line:

@extensions{@$extension_list_reference} = ();

Note: each value of the hash is empty, but you still can check whether the key exists in the hash using function exists , like this:

if(exists $extensions{$some_key}) {...

PS If by some reason you really need those strings 'include' as values, you can have them, too:

@extensions{@$extension_list_reference} = ('include') x @$extension_list_reference;

Answer 4

This way:

read_config($config_file => my %config);
%extensions = map +($_ => "include"), @{$config{extensions}{ext}};

or this way:

read_config($config_file => my %config);
@extensions{@{$config{extensions}{ext}}} = ("include") x @{$config{extensions}{ext}};