从文件夹中的最新文件中提取数据

Question

Trying to use the most recent file in folder for data.

My problem is that my master excel file wont use the data from the most recent data file (xlsx) to pull the data. My code currently has the name of the current file (eg. "Network-2019.xlsm" ) but lets say i insert a file called "network.xlsm, which is posted in the folder later. I want main dataset to recognize this and pull in that data.

Function GetMostRecentExcelFile(ByVal myDirectory As String, ByVal filePattern As String) As String

    Dim fso As Object
    Set fso = CreateObject("Scripting.FileSystemObject")

    Dim myFolder As Object
    Set myFolder = fso.getfolder(IIf(Right(myDirectory, 1) = "\", myDirectory, myDirectory & "\"))

    Dim currentDate As Date
    Dim fname As String

    Dim currentFile As Object
    For Each currentFile In myFolder.Files
        If (currentDate = CDate(0) Or currentFile.DateCreated > currentDate) And currentFile.name Like filePattern _
            And InStr(LCase$(currentFile.name), ".xlsx") > 0 And InStr(currentFile.name, "~$") = 0 Then

            currentDate = currentFile.DateCreated
            fname = currentFile.name

        End If
    Next currentFile

    GetMostRecentExcelFile = fname

End Function

Answer 1

I would suggest something like below, since you are using the FileSystemObject

Note that I used early binding. The associated intellisense is quite useful, and you can always change to late binding if you need to for any reason.

Option Explicit
Function GetMostRecentExcelFile(sFolderPath As String) As String
    Dim FSO As FileSystemObject
    Dim FO As Folder, FI As File, recentFI As File

Set FSO = New FileSystemObject
Set FO = FSO.GetFolder(sFolderPath)

For Each FI In FO.Files
    Select Case FI.Name Like "*.xlsx"
        Case True
            Select Case recentFI Is Nothing
                Case True
                    Set recentFI = FI
                Case False
                    If FI.DateCreated > recentFI.DateCreated Then
                        Set recentFI = FI
                    End If
            End Select
    End Select
Next FI

GetMostRecentExcelFile = recentFI.Path
End Function