Excel VBA 中所需的对象

Question

I am trying to get the user to enter sheet name and based on the input I want selected cell value to be copied from one sheet to another sheet to a new row.

This is for a basic excel functioning system

Set nextCellInColumn = Worksheets("Summary").Cells(Rows.Count, 4).End(xlUp).Offset(1, 0)
strName = Application.InputBox("Please enter")
nextCellInColumn.Value = Worksheets.Application.InputBox("Please enter").Range("I5").Value
Worksheets.Application.InputBox("Please enter").Range("I5").Copy Worksheets("Summary").Range("D6")

Answer 1

You need to test if the worksheet name exists that the user entered otherwise the copy will fail. Also if the user presses the Cancel button the InputBox will return a boolean False . You need to check for that and eg exit, or your code fails too.

Option Explicit

Public Sub Test()
    Dim wsSummary As Worksheet
    Set wsSummary = ThisWorkbook.Worksheets("Summary")

    Dim NextCellInColumn As Range
    Set NextCellInColumn = wsSummary.Cells(wsSummary.Rows.Count, 4).End(xlUp).Offset(1, 0)

    Dim strName As Variant 'if user presses cancel it will return a boolean false
    strName = Application.InputBox("Please enter")

    If VarType(strName) = vbBoolean And strName = False Then Exit Sub 'user pressed cancel so exit

    If WorksheetExists(strName) Then
        NextCellInColumn.Value = ThisWorkbook.Worksheets(strName).Range("I5").Value
        ThisWorkbook.Worksheets(strName).Range("I5").Copy wsSummary.Range("D6")
    Else
        MsgBox "Worksheet '" & strName & "' not found.", vbCritical
    End If
End Sub

'check if a worksheet exists
Public Function WorksheetExists(ByVal WorksheetName As String, Optional ByVal wb As Workbook) As Boolean
    If wb Is Nothing Then Set wb = ThisWorkbook 'default to thisworkbook

    Dim ws As Worksheet
    On Error Resume Next
    Set ws = wb.Worksheets(WorksheetName)
    On Error GoTo 0

    WorksheetExists = Not ws Is Nothing
End Function