如果特定列名称下的单元格为空，如何删除整行的空白？

Question

I need to import several xml-files into Excel and I need to align the column names for all of the xml-tables that are pasted in Excel. The problem is that some of the xml-files include one additional column, which I do not need. This column pops up in the middle of the table, and therefor makes it difficult to work with the data. In addition, I need to remove the entire row if the cells under the name "content" is blank.

So far I have managed to make a command button which imports the xml-files to Excel (see code).

Sub CommandButton1_Click()    
    Dim xWb As Workbook
    Dim xSWb As Workbook
    Dim xStrPath As String
    Dim xFileDialog As FileDialog
    Dim xFile As String
    Dim xCount As Long
    On Error GoTo ErrHandler
    Set xFileDialog = Application.FileDialog(msoFileDialogFolderPicker)
    xFileDialog.AllowMultiSelect = False
    xFileDialog.Title = "Select a folder [Kutools for Excel]"
    If xFileDialog.Show = -1 Then
        xStrPath = xFileDialog.SelectedItems(1)
    End If
    If xStrPath = "" Then Exit Sub
    Application.ScreenUpdating = False
    Set xSWb = ThisWorkbook
    xCount = 1
    xFile = Dir(xStrPath & "\*.xml")
    Do While xFile <> ""
        Set xWb = Workbooks.OpenXML(xStrPath & "\" & xFile)
        xWb.Sheets(1).UsedRange.Copy xSWb.Sheets(1).Cells(xCount, 1)
        xWb.Close False
        xCount = xSWb.Sheets(1).UsedRange.Rows.Count + 2
        xFile = Dir()
    Loop
    Application.ScreenUpdating = True
    xSWb.Save
    Exit Sub

ErrHandler:
    MsgBox "no files xml", , "Kutools for Excel"
End Sub

I hope to get 30 tables from 30 xml-files, with similar headers in the same columns. In addition, I need to remove the empty cells i referred to since the data sets are somewhat huge.

Answer 1

Try to seek for that additional column using for example Instr() in the header row of opened workbook - only if You know the header name of this column. Do this in xWb workbook and after corrections copy paste to your main workbook. Referring to remove empty cells action, You can do this after pasting to main file. Just do the simple if() instruction checking if the cell in specified column is blank - "" (double quotes). You can put this if() in loop from 2 to last row - that last row You can 'measure' in xWb using xWb.cells(rows.count,1).end(xlup).Row. Give me a sign if You managed to do anything.

Answer 2

This may help you:

Option Explicit

Sub test()

    Dim ColumnName As String
    Dim LastColumn As Long, LastRow As Long
    Dim rngFoundContent As Range
    Dim rngFoundColumn As Range

    'Change sheet name if needed
    With ThisWorkbook.Worksheets("Sheet1")

        'Search for the word "Content"
        Set rngFoundContent = .UsedRange.Find("Content", LookIn:=xlValues)
        'If "Content" found
        If Not rngFoundContent Is Nothing Then
            'Delete the row below
            .Rows(rngFoundContent.Row + 1).EntireRow.Delete
        End If

        'Search for the Column Name (Lest us assume that column name is "Test"0
        ColumnName = "Test"
        'Let us assume that Headers appear in row 1, find the last column of row 1
        LastColumn = .Cells(1, .Columns.Count).End(xlToLeft).Column
        'Search for the word column Test
        Set rngFoundColumn = .Range(.Cells(1, 1), .Cells(1, LastColumn)).Find(ColumnName, LookIn:=xlValues)
        'If column found
        If Not rngFoundColumn Is Nothing Then
            'Delete whole column
            .Columns(rngFoundColumn.Column).EntireColumn.Delete
        End If

    End With

End Sub