根据子文件夹中的文件类型创建子文件夹，然后移动该类型的所有文件

Question

I have a folder in My Documents called Misc, and in that folder is 400 subfolders which has become a bit of a mess. Within each of those subfolders are different file types, i'd like to be able to create subfolders in each subfolder based on the filetype, and move anything of that file type into the new subfolder.

So i'd like to have something like this:

C:\Users\Personal\Documents\Misc\
 - Subfolder1
  - PDF
  - PNG
  - PDF
- Subfolder2
  - XLSX
  - DOCX
  - PDF
- Subfolder3
  - M4A
  - MKV
  - PNG

There's no consistency with what file types are in each subfolder which is where i'm having trouble. Is this even possible to do?

So far what i've been doing is going into each folder and running the following batch file

for %%a in (.) do md "%%~na PNG" &move "*.png" ".\%%~na PNG\"
for %%a in (.) do md "%%~na Documents" &move "*.docx" ".\%%~na Documents\"
for %%a in (.) do md "%%~na PDF" &move "*.pdf" ".\%%~na PDF\"
for %%a in (.) do md "%%~na Spreadsheets" &move "*.xlsx" ".\%%~na Spreadsheets\"

Each time I come across a new file extension, I add a new line. But ideally i'd only want the folders creating if the file extension is in the folder, and I wouldn't have to manually go into each folder to run it.

Answer 1

Your for loops do not access the file system because there are no wildcards , so they iterate only once and return . in their meta-variable %%a .

Anyway, not sure if I understood correctly what you want, but give the following code a try:

@echo off
rem // Iterate through all immediate sub-directories of the target root directory:
for /D %%D in ("%UserProfile%\Documents\Misc\*") do (
    rem // Iterate through all files in each sub-directory:
    for %%F in ("%%~D\*.*") do (
        rem /* Remove the leading `.` from the name extension of the current file;
        rem    if the files has got no extension, this loop does not iterate: */
        for /F "tokens=* delims=." %%E in ("%%~xF") do (
            rem /* Create sub-directory from file name extension;
            rem    suppress errors if it already exists from previous iteration: */
            md "%%~D\%%E" 2> nul
            rem // Actually move the current file into the sub-directory:
            move /Y "%%~F" "%%~D\%%E"
        )
    )
)

Answer 2

As your use of tags was limited to just cmd , and the answer you've already accepted is a batch-file , I have updated the tags you've used and included this powershell example based upon your stated requirements:

$ds=GCI "C:\Users\Personal\Documents\Misc"|?{$_.PSIsContainer}|Select -Exp FullName
ForEach($f In $ds){
    $gs=GCI $f|?{(!($_.PSIsContainer))}|Group Extension
    ForEach($g In $gs){
        $n=Join-Path $f($g.Name.Substring(1,($g.Name.Length-1)))
        If(-Not(Test-Path $n)){[Void](MD $n)}
        $g.Group|Move -Dest $n
    }
}