X秒后如何使cmd命令超时

Question

Using command prompt, I need to open a folder on a network location in File Explorer, and if it's not available then exit the command prompt window I ran the command from. The problem is trying to open a network location that isn't there takes extremely long (30+ seconds), and when it is there it opens immediately, so I want to try opening the location and exit after 5 seconds.

I've already tried using taskkill but it seems accessing a network location prevents it from working the way it should, also taskkill seems to kill all command prompt windows which isn't ideal. To replicate, type the following command (using an inaccessible network location) and it should take a while to finish

if exist \\\\1.2.3.4\\c$ (start \\\\1.2.3.4\\c$) else exit

Answer 1

When using start command/program/path , CMD will not directly launch the Explorer with the given path. Before that it, has to examine the given parameter to determine its type (Internal command, External executable or script, some other type of file or folder)

Depending on the type it may launch it directly or attempt to open it using ShellExecute API. The ShellExecute API in turn examines the given object to determine which application should be used to open it. If the object is a path to a local or remote folder, then it uses explorer to open that location.

When dealing with the path to an unavailable network share, it will take a while for CMD (and ShellExecute) to finally determine that network share is inaccessible, Therefor the execution of your CMD command will be blocked during that time.

To circumvent the blocking, you need to open the network share asynchronously using a new instance of CMD and then attempt to terminate that instance after the timeout period.

Using taskkill to terminate that instance, it should be given a unique title in order to distinguish from other processes.

A very basic and simple solution would be using a batch file such as follows

:: ExploreShare.cmd
@echo off
setlocal
set "sharedLoc=%~1"
:: Basic validation
if not defined sharedLoc exit /b
if not "%sharedLoc:~0,2%"=="\\" exit /b

set "uniqTitle=ExploreShare-%time: =%-%random%"
start "%uniqTitle%" /min "CMD " /c start "" "%sharedLoc%"
>nul timeout /t 5
taskkill /fi "WINDOWTITLE eq %uniqTitle%" /f >nul 2>&1

It can be used from command line like this

> ExploreShare \\127.0.0.1\C$

The drawback of using such basic a solution is that It will wait for 5 seconds regardless, and except by visual determination from user, does not offer any way to determine if the operation was successful or not.

It can be improved by a slightly more complex script which will try to minimize the wait time on successful operation and also provides a mechanism to determine success or failure.

:: ExploreShare2.cmd
@echo off
setlocal
set "sharedLoc=%~1"
:: Basic validation
if not defined sharedLoc exit /b 1
if not "%sharedLoc:~0,2%"=="\\" exit /b 1

set "uniqTitle=ExploreShare-%time: =%-%random%"
echo Attempting to open network share "%sharedLoc%" ...
start "%uniqTitle%" /min "CMD " /c if exist "%sharedLoc%" (start "" "%sharedLoc%") else pause
>nul timeout /t 1
set "childProc="
for /F "skip=2" %%A in ('tasklist /fi "WINDOWTITLE eq %uniqTitle%"') do set "childProc=%%A"
if not defined childProc (
    echo The operation completed successfully.
    exit /b 0
)
:: Give it another 4 seconds
>nul timeout /t 4
set "childProc="
for /F "skip=2" %%A in ('tasklist /fi "WINDOWTITLE eq %uniqTitle%"') do set "childProc=%%A"
if defined childProc (
    >&2 echo The operation timed out.
    taskkill /fi "WINDOWTITLE eq %uniqTitle%" /f >nul 2>&1
    exit /b 1
) else (
    echo The operation completed successfully.
    exit /b 0
)

So for example if you need to terminate the CMD/BatchFile on failure it can be used like this

From command line:

> ExploreShare2 "\\server\share" || exit

Within a batch file:

call ExploreShare2 "\\server\share" || exit /b