计算单词数并指定行

Question

It is required to make a file with the number of words encountered (for example, Word1 and Word2 ) from another file and specify the lines where these words occur in this format:

Word1: 35 [25, 50, 300, ...]    
Word2: 15 [10, 25, 65, ...]    

Answer 1

Your question unfortunately lacks sample input files that demonstrates all the sorts of things you need to handle and the expected output based on them, so I'm just making up some stuff.

Given the files

wordlist.txt :

cat
dog
fish
horse

and input.txt :

There are three fish.
Two red fish.
One blue fish and a brown dog.
There are no matching words on this line.
Also there is no cat, only the dog. Oh, there is a white dog too.
There are doggies.

this perl script will print the matching words and their lines, including multiple matches of a word per line:

#!/usr/bin/env perl
use warnings;
use strict;
use autodie;
use feature qw/say/;
use English;

my %words;

open my $wordlist, "<", $ARGV[0];
while (<$wordlist>) {
    chomp;
    $words{$_} = [];
}

open my $text, "<", $ARGV[1];
while (<$text>) {
    while (my ($word, $positions) = each %words) {
        while (m/\b\Q$word\E\b/g) { # Match all occurrences of the word by itself
            push @$positions, $NR;
        }
    }
}

$OFS = ' ';
for my $word (sort keys %words) {
    my $positions = $words{$word};
    say "$word:", scalar(@$positions), join(',', @$positions);
}

Example:

$ perl words.pl wordlist.txt input.txt
cat: 1 5
dog: 3 3,5,5
fish: 3 1,2,3
horse: 0