如何使用mysql查询将datagridview中的文本框列替换为复选框列

Question

I have this problem where I want to convert textbox column to checkbox in vb.net. The data is from mysql and I want one column to be displayed as checkbox column.

Here is my code so far:

Private Sub data_load()

     Dim mycommand As New MySqlCommand
     Dim myadapter As New MySqlDataAdapter
     Dim mydata As New DataTable

     conn = New MySqlConnection
     conn.ConnectionString = connstr

     conn.Open()

     mycommand.Connection = conn
     mycommand.CommandText = "SELECT locator_id, name AS 'NAME', date AS 'DATE', destination AS 'DESTINATION', time_leave AS 'TIME LEAVE', time_return AS 'TIME RETURN', isOfficial AS 'OFFICIAL?' FROM locator_table ORDER BY locator_id DESC"

     myadapter.SelectCommand = mycommand
     myadapter.Fill(mydata)

     DataGridView1.DataSource = mydata
     DataGridView1.Refresh()
End Sub

This is the image:

As you can see Official? column is not checkbox.

Now, I want Official? to be checkbox column. The value in Official? column is only 1 and 0. When the value is 1 checkbox should be check otherwise uncheck. How to achieve this?

Answer 1

You can add the columns to the DataTable manually specifying the Boolean datatype for the OFFICIAL? column. When the DataTable is bound to the grid it will display check boxes.

You can pass your connection string directly to the constructor of the connection and pass the command text and connection directly to the constructor of the command. The Using...End Using blocks ensure that the database objects are closed and disposed even if there is an error.

If you need a DataAdapter later to Update the database you can create one then.

Private Sub data_load()
    Dim mydata As New DataTable
    mydata.Columns.Add("locator_id", GetType(Integer))
    mydata.Columns.Add("NAME", GetType(String))
    mydata.Columns.Add("DATE", GetType(Date))
    mydata.Columns.Add("DESTINATION", GetType(String))
    mydata.Columns.Add("TIME LEAVE", GetType(String))
    mydata.Columns.Add("TIME RETURN", GetType(String))
    mydata.Columns.Add("OFFICIAL?", GetType(Boolean))
    Using conn As New MySqlConnection(constr)
        Using mycommand As New MySqlCommand("SELECT locator_id, name AS 'NAME', date AS 'DATE', destination AS 'DESTINATION', time_leave AS 'TIME LEAVE', time_return AS 'TIME RETURN', isOfficial AS 'OFFICIAL?' FROM locator_table ORDER BY locator_id DESC", conn)
            conn.Open()
            mydata.Load(mycommand.ExecuteReader)
        End Using
    End Using
    DataGridView1.DataSource = mydata
End Sub