Groovy：在静态类闭包内部访问全局变量

Question

I'm running the below code snippet and not sure how to resolve accessing the tr variable inside a static method of a class returning closure.

tr = 'GROOVY'

class tmp {
    static map = {
        def cols = [ header: { "JAVA" }, trailer: { tr } ]
    }
}

tmp.map().collect { k,v -> println v()} 

Threw the below error when I ran it.

JAVA
Caught: groovy.lang.MissingPropertyException: No such property: tr for class: tmp
Possible solutions: map
groovy.lang.MissingPropertyException: No such property: tr for class: tmp
Possible solutions: map
    at tmp$__clinit__closure1$_closure3.doCall(test.groovy:31)
    at tmp$__clinit__closure1$_closure3.doCall(test.groovy)
    at test$_run_closure1.doCall(test.groovy:35)
    at test.run(test.groovy:35)
[Finished in 2.0s with exit code 1]

Answer 1

Your static block is shared among all instances of class Tmp . It is normal that the closure defined in this scope cannot access an instance variable of a specific instance, right?

However you can fix this by using the delegation mechanism in groovy closures.

class Context {
    String tr="GROOVY"
}

class Tmp {
    static map = {
        def cols = [ header: { "JAVA" }, trailer: { tr } ]
    }
}

class Runner {
    void run(Context ctx) {
        //we need to clone this closure, because it is a shared (static) closure
        //other threads may try to run this method concurrently, and because
        //we are going to alter the closure's internal state by setting it's delegate
        Closure map=Tmp.map.clone()
        map.resolveStrategy=Closure.DELEGATE_FIRST
        map.delegate=ctx

        map().collect { k,v -> println "k:$k, v:${v()}"}
    }
}

new Runner().run(new Context())

Answer 2

Your groovy file is being compiled to something like this:

class Script1 extends Script {

    class tmp {
        static map = {
            def cols = [ header: { "JAVA" }, trailer: { tr } ]
        }
    }

    def run() {
        tr = 'GROOVY'
        tmp.map().collect { k,v -> println v()} 
    }

}

Can you see why tr can't be found by class tmp ?

Answer 3

You can make use of the Groovy Binding class object. It is used to pass values in and out of the Groovy scripts. By default there is one readily usable binding object available for the scripts. The properties declared outside the classes are added automatically to this object.

tr = 'GROOVY'

class Tmp {
    static Binding context
    static map = {
        def cols = [header: { "JAVA" }, trailer: { context.tr }]
    }
}

Tmp.context = binding
Tmp.map().collect { k, v -> println v() } 

It is better to create your own binding object (or should I say context) instead of relying on the default one as follows:

def myBinding = new Binding(['tr': 'Groovy'])

class Tmp {
    static Binding context
    static map = {
        def cols = [header: { "JAVA" }, trailer: { context.tr }]
    }
}

Tmp.context = myBinding
Tmp.map().collect { k, v -> println v() }