批量获取确切的Windows版本

Question

I need to get the exact Windows build of my os in a batch-file and I want to store it as a variable. I need the full build like 14393.3144 (displayed if winver is used), because I want to check if an update was successfully installed. I've already tryed using wmic os get buildnumber but it only returns 14393. Additionally to this I thought about reading the Windows Update log but creating it with the powershell command Get-WindowsUpdateLog simply takes to much time and isn't reliable enough.

Answer 1

Here's an example which retrieves the full version using wmic :

@Set "OSVer="
@For /F EOL^=V %%A In ('"%__AppDir__%wbem\WMIC.exe" OS Get Version 2^>NUL')Do @For %%B In (%%A)Do @Set "OSVer=%%B"
@Set OSVer 2>NUL&&Pause

On a test machine, this has just returned 10.0.18362

---

You could of course use the internal Ver command, (which technically returns the version of cmd.exe , not the OS) :

@Set "OSVer="
@For /F Delims^=] %%A In ('Ver')Do @For %%B In (%%A)Do @Set "OSVer=%%B"
@Set OSVer 2>NUL&&Pause

On a test machine, this has just returned 10.0.18362.295

---

You could of course try parsing the registry for the information too:

 @Set "RKey=HKLM\\SOFTWARE\\Microsoft\\Windows NT\\CurrentVersion" @For /F Tokens^=2* %%A In ('^""%__AppDir__%reg.exe" Query "%RKey%" /V CurrentBuildNumber^" 2^>NUL')Do @Set "NUM=%%B" @For /F Tokens^=2* %%A In ('^""%__AppDir__%reg.exe" Query "%RKey%" /V UBR^" 2^>NUL')Do @Set /A UBR=%%B 2>NUL @Echo(%NUM%.%UBR%&Pause 

On a test machine, this has just returned 18362.295

---

Alternatively, take a look at this Super User question and answers.

Answer 2

Use ver . The output is like what you want.

> C:\Users\user>ver
> 
> Microsoft Windows [Version 10.0.17763.678]