如何在XSLT-1.0中连接XML标签？

Question

I tried to process an XML file with this XSLT-1.0 file.
I would like to concat all of the <pr> tags in the same cell of the table.

Here is my XML:

<?xml version="1.0" encoding="ISO-8859-1"?>
<cours>
    <sigle>GEN1051</sigle>
    <titre>Ingénierie et entreprises II</titre>
    <prgs>
        <pr>4108</pr>
        <pr>7643</pr>
        <pr>7833</pr>
    </prgs>
    <credits>3</credits>
</cours>

I tried it with the function xsl:choose and fn:concat , but of course, this didn't work, because that makes three empty cells instead of one cell with my 3 values of <pr> tags.

This is a part of my XSLT:

<xsl:for-each select="prgs/pr">
    <xsl:choose>
        <xsl:when test="pr = 1">
            <td>
                <xsl:value-of select="."/>
            </td>
            <xsl:otherwise>
                <td>
                    <xsl:value-of select='concat(pr, pr)'/>
                </td>
            </xsl:otherwise>
        </xsl:when>
    </xsl:choose>
</xsl:for-each>

Who knows a better solution to this problem?

Answer 1

You can use the following XSLT-1.0 stylesheet:

<?xml version="1.0" encoding="ISO-8859-1"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

    <!-- Identity template -->
    <xsl:template match="node()|@*">
        <xsl:copy>
            <xsl:apply-templates select="node()|@*" />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="prgs">
        <xsl:copy>
            <td>
                <xsl:for-each select="pr">
                    <xsl:value-of select="." />
                </xsl:for-each>
            </td>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

Its output is:

<?xml version="1.0"?>
<cours>
    <sigle>GEN1051</sigle>
    <titre>Ingénierie et entreprises II</titre>
    <prgs>
        <td>410876437833</td>
    </prgs>
    <credits>3</credits>
</cours>

It concatenates the values of all three <pr> elements in one <td> element.

If you want to separate your <pr> values, just put a

<xsl:if test="position() != last()"><xsl:text> - </xsl:text></xsl:if>

after the <xsl:value-of select="." /> <xsl:value-of select="." /> in the xsl:for-each loop.

Answer 2

If you want to put all three pr values in the same cell, you can do simply:

In XSLT 1.0:

<td>
    <xsl:for-each select="prgs/pr">
        <xsl:value-of select="." />
        <xsl:if test="position() != last()">; </xsl:if>
    </xsl:for-each>
</td>

In XSLT 2.0:

<td>
    <xsl:value-of select="prgs/pr" separator="; "/>
</td>

The output of both will be:

<td>4108; 7643; 7833</td>

---

This is assuming you are in the context of cours (as your snippet indicates).