从亚马逊的搜索页面请求基于时间的值

Question

The code I'm using below will return/capture the keyword/phrase suggestions from Amazon's search bar. The problem is that there seems to be time based values in the parameters used to construct the output. Can I use a GET request to obtain the current time based values, or is there a better method? The code below is used in conjunction with JSonParser to get the suggestions. The result I'm looking for is the output of the code to match the drop down results from the Amazon search bar.

Option Explicit

Public Sub GetTable()

    Dim json As Object, suggestion As Object                '<  VBE > Tools > References > Microsoft Scripting Runtime
    Const SEARCH_TERM As String = "TRAVEL"
    Const SEARCH_TERM2 As String = "BOOKS"
    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", "https://completion.amazon.com/api/2017/suggestions?session-id=141-0042012-2829544" & _
        "&customer-id=&request-id=7E7YCB7AZZM1HQEZF2G1&page-type=Search&lop=en_US&site-variant=" & _
        "desktop&client-info=amazon-search-ui&mid=ATVPDKIKX0DER&alias=aps&b2b=0&fresh=0&ks=76&" & _
        "prefix=" & SEARCH_TERM & "&event=onKeyPress&limit=11&fb=1&suggestion-type=KEYWORD&suggestion-type=" & _
        "WIDGET&_=1556820864750", False
        .setRequestHeader "User-Agent", "Mozilla/5.0"
        .send
        Set json = JsonConverter.ParseJson(.responseText)("suggestions")
    End With

    For Each suggestion In json
        Debug.Print suggestion("value")
    Next
End Sub

Answer 1

Those params values can be removed except the session-id. They are actually cookies values. For the session-id you can generate a value for far into the future and that should last for a while.

Option Explicit

Public Sub GetTable()
    Dim json As Object, suggestion As Object, suggestions As Scripting.Dictionary '<  VBE > Tools > References > Microsoft Scripting Runtime
    Const SEARCH_TERM As String = "TRAVEL"
    Const SEARCH_TERM2 As String = "BOOKS"

    Set suggestions = New Scripting.Dictionary
    With CreateObject("MSXML2.XMLHTTP")
        .Open "GET", "https://completion.amazon.com/api/2017/suggestions?session-id=999-5000000-8000000" & _
        "&customer-id=&request-id=&page-type=Search&lop=en_US&site-variant=" & _
        "desktop&client-info=amazon-search-ui&mid=ATVPDKIKX0DER&alias=aps&b2b=0&fresh=0&ks=76&" & _
        "prefix=" & SEARCH_TERM & "&event=onKeyPress&limit=11&fb=1&suggestion-type=KEYWORD&suggestion-type=" & _
        "WIDGET&_=", False
        .setRequestHeader "User-Agent", "Mozilla/5.0"
        .send
        Set json = JsonConverter.ParseJson(.responseText)("suggestions")
    End With
    suggestions(json(1)("widgetItems")(1)("metadata")("text")) = vbNullString
    For Each suggestion In json
        suggestions(suggestion("value")) = vbNullString
    Next
    Dim key As Variant
    For Each key In suggestions.keys
        Debug.Print key
    Next key
End Sub