对为 4 个内部连接外部表创建的内部表使用字段符号

Question

Allegedly use of field-symbols might result in better performance, however I have very scarce experiences with pointers and don't quite understand the concept of pointers.

I have this program which selects carrid , connid , fldate , bookid and travel agency's name from the table created by INNER JOIN of tables spfli , sflight , sbook and travelag , based on 2 user inputs ( parameters ):

• cityFrom
• cityTo

Basically, I want the user to insert from where he wants to take off and in which city he wants to land. After that the program displays all flights that are possible to book.

Here is my code (works fine), that I would like to refactor by using FIELD-SYMBOLS:

TABLES spfli.

DATA: BEGIN OF wa,
        carrid TYPE spfli-carrid,
        connid TYPE spfli-connid,
        fldate TYPE sflight-fldate,
        bookid TYPE sbook-bookid,
        name TYPE stravelag-name,
      END OF wa,
      itab LIKE SORTED TABLE OF wa
                WITH UNIQUE KEY carrid connid fldate bookid.

PARAMETERS: fromLoc TYPE spfli-cityfrom,
            toLoc TYPE spfli-cityto.

SELECT  p~carrid p~connid f~fldate b~bookid a~name
  INTO  CORRESPONDING FIELDS OF TABLE itab
  FROM  ( ( (
          spfli AS p
          INNER JOIN sflight AS f ON p~carrid = f~carrid AND
                                     p~connid = f~connid
        )
          INNER JOIN sbook AS b ON b~carrid = f~carrid AND
                                   b~connid = f~connid AND
                                   b~fldate = f~fldate
        ) 
          INNER JOIN stravelag AS a ON b~agencynum = a~agencynum
        )
  WHERE p~cityfrom = fromLoc AND
        p~cityto   = toLoc  AND
        f~seatsmax > f~seatsocc.

LOOP AT itab INTO wa.
  AT NEW fldate.
    ULINE.
    WRITE: / .
    WRITE: 'FLIGHT' COLOR 4.
    ULINE.
    WRITE: / wa-carrid COLOR 3, wa-connid COLOR 3, wa-fldate COLOR 3.
    WRITE: / .
    WRITE: 'Booking ID' COLOR 3, 30 'Carrier ID' COLOR 3, 60 'Air Connection ID' COLOR 3, 90 'Travel Agency' COLOR 3.
    ULINE.
ENDAT.
  WRITE: / wa-bookid, 30 wa-carrid, 60 wa-connid, 90 wa-name.
ENDLOOP.

I started by declaration of field-symbols I thought I will need and then I assigned them to tables. After that i tried to declare PARAMETERS and specify their type based on newly created field-symbols, but it did not work - program says: "Type <FS_SPFLI>" is unknown.

DATA: BEGIN OF wa,
        carrid TYPE spfli-carrid,
        connid TYPE spfli-connid,
        fldate TYPE sflight-fldate,
        bookid TYPE sbook-bookid,
        name TYPE stravelag-name,
      END OF wa,
      itab LIKE SORTED TABLE OF wa
                WITH UNIQUE KEY carrid connid fldate bookid.

FIELD-SYMBOLS: <fs_spfli> TYPE any,
               <fs_wa> TYPE any.

ASSIGN: spfli TO <fs_spfli>,
        wa TO <fs_wa>.

PARAMETERS: fromLoc TYPE <fs_spfli>-cityfrom,
            toLoc TYPE <fs_spfli>-cityto.

I would appreciate a guidance trough how to make my program work with field-symbols

Answer 1

A field symbol is not a type, it's a kind of alias to the data object (variable) assigned at runtime (it's a kind of reference variable).

So, you can't write:

PARAMETERS: fromLoc TYPE <fs_spfli>-cityfrom,
            toLoc TYPE <fs_spfli>-cityto.

Instead, use the actual type (SPFLI is a type defined in the ABAP Dictionary, via the transaction code SE11 ) :

PARAMETERS: fromLoc TYPE spfli-cityfrom,
            toLoc TYPE spfli-cityto.

A field symbol should be typed the most precisely possible rather than generically.

In your case, instead of using the generic ANY type, you should write (here, I use LIKE variable , because there's no "standalone type" explicitly defined):

FIELD-SYMBOLS: <fs_spfli> LIKE wa.

NB: no need to prefix the field symbols with fs , they are identified clearly thanks to the angle brackets ( <spfli> ).

A field symbol may be assigned by using one of these statements:

• ASSIGN ... TO ...
• LOOP AT ... ASSIGNING ...
• READ TABLE ... ASSIGNING ...
• APPEND ... TO ... ASSIGNING
• INSERT ... INTO ... ASSIGNING
• MODIFY ... FROM ... ASSIGNING

A field symbol may be assigned by using this statement:

• UNASSIGN

Answer 2

You declared your field symbols as type ANY , this is like void * in C++ (pointing into the void, the compiler expects that someting will begin there but has no knowledge what it is exactly). There is absolutely no way for the compiler to know that those field symbols have in fact type spfli or the one of wa until the run time.

This one would compile.

FIELD-SYMBOLS: <fs_spfli> TYPE spfli,
               <fs_wa> LIKE wa.

ASSIGN: spfli TO <fs_spfli>,
        wa TO <fs_wa>.

PARAMETERS: fromLoc LIKE <fs_spfli>-cityfrom,
            toLoc LIKE <fs_spfli>-cityto.

And here the full compilable program.

REPORT ZZZ.

TABLES spfli.

DATA: BEGIN OF wa,
        carrid TYPE spfli-carrid,
        connid TYPE spfli-connid,
        fldate TYPE sflight-fldate,
        bookid TYPE sbook-bookid,
        name TYPE stravelag-name,
      END OF wa,
      itab LIKE SORTED TABLE OF wa
                WITH UNIQUE KEY carrid connid fldate bookid.

FIELD-SYMBOLS: <fs_spfli> TYPE spfli,
               <fs_wa> LIKE wa.

ASSIGN: spfli TO <fs_spfli>,
        wa TO <fs_wa>.

PARAMETERS: fromLoc LIKE <fs_spfli>-cityfrom,
            toLoc LIKE <fs_spfli>-cityto.

SELECT  p~carrid p~connid f~fldate b~bookid a~name
  INTO  CORRESPONDING FIELDS OF TABLE itab
  FROM  ( ( (
          spfli AS p
          INNER JOIN sflight AS f ON p~carrid = f~carrid AND
                                     p~connid = f~connid
        )
          INNER JOIN sbook AS b ON b~carrid = f~carrid AND
                                   b~connid = f~connid AND
                                   b~fldate = f~fldate
        )
          INNER JOIN stravelag AS a ON b~agencynum = a~agencynum
        )
  WHERE p~cityfrom = fromLoc AND
        p~cityto   = toLoc  AND
        f~seatsmax > f~seatsocc.

LOOP AT itab INTO wa.
  AT NEW fldate.
    ULINE.
    WRITE: / .
    WRITE: 'FLIGHT' COLOR 4.
    ULINE.
    WRITE: / wa-carrid COLOR 3, wa-connid COLOR 3, wa-fldate COLOR 3.
    WRITE: / .
    WRITE: 'Booking ID' COLOR 3, 30 'Carrier ID' COLOR 3, 60 'Air Connection ID' COLOR 3, 90 'Travel Agency' COLOR 3.
    ULINE.
ENDAT.
  WRITE: / wa-bookid, 30 wa-carrid, 60 wa-connid, 90 wa-name.
ENDLOOP.

Answer 3

If you are on 4.70 or higher you can write.

LOOP AT itab ASSIGNING FIELD-SYMBOL(<wa>).
  WRITE: / <wa>-bookid, 30 <wa>-carrid, 60 <wa>-connid, 90 <wa>-name.
ENDLOOP.

Then ABAP will take care of proper typing on its own. If you do not understand pointers then you may pretend that a field-symbol is just an alias for the structure it is pointing at.