从定义范围转换Excel宏，以选择的细胞仅操作上？

Question

I have a macro that does what I want but it runs on a set range of cells. I have been trying to make it run only on cells that are selected (highlighted) by the user. I've tried various combinations of defining the range using Dim Rng as Range and also Selection method. Me:No VBA experience to speak of, some python experience.

Working code (defined range)

Sub NoHalve()
'
' Macro to remove less-than sign and report only the LOR formatted grey and underlined .
' x = columns, y = rows
    For x = 1 To 200
        For y = 2 To 3000
            If Left(Cells(y, x), 1) = "<" Then
            Cells(y, x) = (Right(Cells(y, x), Len(Cells(y, x)) - 1))
            Cells(y, x).Select
            Selection.Font.ColorIndex = 16
            Selection.Font.Underline = xlUnderlineStyleSingle
            End If
        Next y
    Next x

End Sub

This is my attempt to make it run on user selected cells that gives me object required error for the r.Select line:

Sub NoHalve_selection()

Set Rng = Selection

For Each r In Rng

    If Left(r, 1) = "<" Then
    r = (Right(r, Len(r) - 1))
    r.Select
    Selection.Font.ColorIndex = 16
    Selection.Font.Underline = xlUnderlineStyleSingle
    End If
Next
End Sub

Answer 1

You're nearly there

Sub NoHalve_selection()
    Dim r As Range, Rng As Range
    Set Rng = Selection

    For Each r In Rng.Cells ' .Cells is implied in For Each r in Rng
        With r  'Using With block is more efficient as it does fewer lookups to Excel
            If Left$(.Value, 1) = "<" Then  ' .Value uses the With block (so is the same as r.Value).  Value is the default property of a Range 
                .Value = Mid$(.Value, 2)
                .Font.ColorIndex = 16
                .Font.Underline = xlUnderlineStyleSingle
            End If
        End With
   Next
End Sub

_{Original post for comparison}

Sub NoHalve_selection()
    Dim r As Range, Rng As Range
    Set Rng = Selection

    For Each r In Rng
        If Left(r, 1) = "<" Then
            r = (Right(r, Len(r) - 1))
            r.Font.ColorIndex = 16
            r.Font.Underline = xlUnderlineStyleSingle
        End If
   Next
End Sub

Answer 2

This should be relatively easy by replacing the hard coded numbers with Selection.Columns.Count and Selection.Rows.Count .

Sub NoHalve()
'
' Macro to remove less-than sign and report only the LOR formatted grey and underlined .
' x = columns, y = rows
    For x = 1 To Selection.Columns.Count
        For y = 2 To Selection.Rows.Count
            If Left(Cells(y, x), 1) = "<" Then
            Cells(y, x) = (Right(Cells(y, x), Len(Cells(y, x)) - 1))
            Cells(y, x).Font.ColorIndex = 16
            Cells(y, x).Font.Underline = xlUnderlineStyleSingle
            End If
        Next y
    Next x
End Sub

If you are making a simple text substitution (removing a sign), as long as that sign is left most then I'd also suggest maybe using something that doesn't rely so heavily on the position of the characters in a string. So something like replace :

Cells(y, x) = replace(Cells(y, x),"<","",,1)

Also I don't believe the line Cells(y, x).Select is required and may change the active selection unnecessarily.