是否可以在FOR / IF语句中回显包含空格的字符串而无需在输出中添加引号？

Question

If you execute this:

if "true" == "true" (
    echo Path is C:\Program Files (x86)\MyFolder
)

You will get an error:

\MyFolder was unexpected at this time.

This is the same if a path is passed to echo as a variable.

There is a solution. This can be fixed by surrounding the text for echo with double quotes (or just the path itself).

However this adds double quotes to the output text:

Path is "C:\Program Files (x86)\MyFolder"

Is there any way to handle this situation without altering output?

Answer 1

As already stated in the comment by @compo , the closing parenthesis is causing the issue as the system thinks it is the closure of your earlier opening parenthesis. You therefore need to escape the parenthesis ^)

However as stated by you, this does not help you when you have an unknown output result, I however do do really understand why the quoted path is problem in the output. but anyway, therefore you need to work around the issue, here are ways, depending on how your actual script layout.

First option, Do not use parenthesized if code block:

if "true" == "true" echo path is %ProgramFiles(x86)%\MyFolder

The above method however will not allow you to do else statements and you would need multple if statements.

The other, better option would be to simply set the variable if there is a match.. Depending on your code blocks, these might require delayedexpansion

if "true" == "true" (
     set "mypath=%ProgramFiles(x86)%\MyPath"
   ) else (
     set "mypath=%ProgramFiles(x86)%\AnotherPath"
 )
echo %mypath%

Answer 2

To echo an arbitrary text including special characters you could assign the text to a variable and then apply delayed variable expansion when echoing:

set "EchoPath=C:\Program Files (x86)\MyFolder"
setlocal EnableDelayedExpansion
if "true" == "true" (
    echo(!EchoPath!
)
endlocal

The setlocal command enables delayed expansion here, the exclamation marks around the variable actually use it. The endlocal command ends delayed expansion. Note that any changes to the variable EchoPath since setlocal become lost past endlocal .

The odd-looking syntax echo( is used here to avoid trouble with certain strings like on and off (which are special keywords), or a string like /? , all of which could theoretically be stored in the variable. Consult also the following threads about that:

• echo. is not working?
• Echo a blank (empty) line to the console from a Windows batch file
• How can I echo a newline in a batch file?