Perl 迭代正则表达式匹配的数量

Question

I have some lines like

int foo[] = { a, b, c, d, e };

The exact numbers of elements in the array is unknown. I want to match it using perl 's regexp. I identify the lines using

if ( $line =~ /^\ *int\ *([a-z]+)\ *\[\]\ *=\ *{(\ *([a-z]+)\ *,?)+}\ *;/ )
{
  print $line;
}

How can I get the number of matches, as I want to work on each of the elements in the array?

Ideally, I would like something like

if ( $line =~ /^\ *int\ *([a-z]+)\ *\[\]\ *=\ *{(\ *([a-z]+)\ *,?)+}\ *;/ )
{
  my $count_of_matches = ??????
  for (my $matches=0 ; $matches<count_of_matches ; $matches++)
  {
    print $matches, "\n";
  }
}

which should result in something like

foo
a
b
c
d
e

I tried

my $count_of_matches = () = $line =~ /.../ # using the same pattern as above

my @list  = $line =~ /.../
my $other_count_of_matches = scalar @list

But I get a count of 3, and the perl array only contains the array name ( foo ) and twice the last element ( e ).

Answer 1

Do it in two steps. First, match the whole contents of {...} , then use split to retrieve the individual elements.

BTW, you don't have to backslash spaces (unless you use the /x modifier).

#!/usr/bin/perl
use warnings;
use strict;
use feature qw{ say };

my $string = 'int foo[] = { a, b, c, d, e };';

my ($array, $elements) = $string =~ /^ *int *([a-z]+) *\[\] *= *\{ *((?:[a-z]+ *,? *)+)\};/;
my @elements = split /[, ]+/, $elements;

say "<$_>" for $array, @elements;

Answer 2

When you find regexes too limiting, use a real C parser.

use MarpaX::Languages::C::Scan qw();
my $ast = MarpaX::Languages::C::Scan->new(
    content => 'int foo[] = { a, b, c, d, e };'
)->ast;
for my $id (
    $ast->findnodes('//declarator//IDENTIFIER'),
    $ast->findnodes('//initializerList//IDENTIFIER')
) {
    say $id->getAttribute('text');
}
__END__
foo
a
b
c
d
e