内部变量的延迟扩展

Question

I am trying to expand some variables inside a for. I don't know how to explain this but I think the code shows pretty well what I want to do.

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

SET arr[0]=C:\Users\me\Desktop\abc
SET arr[1]=C:\Users\me\Desktop\abc2
SET /A arrLastElement=1

CALL :subroutine %arrLastElement% arr
EXIT /B 0

:subroutine
    SET lineToExecute=FORFILES /m "*.*" /c "cmd /c echo !dir!"

    FOR /L %%i in (0, 1, %1) DO (
        SET dir=!%2[%%i]!
        ECHO !dir!
        ECHO !lineToExecute!
    )

    EXIT /B 0

Actual result:

C:\Users\me\Desktop\abc
FORFILES /m "*.*" /c "cmd /c echo "
C:\Users\me\Desktop\abc2
FORFILES /m "*.*" /c "cmd /c echo "

Expected result:

C:\Users\me\Desktop\abc
FORFILES /m "*.*" /c "cmd /c echo C:\Users\me\Desktop\abc"
C:\Users\me\Desktop\abc2
FORFILES /m "*.*" /c "cmd /c echo C:\Users\me\Desktop\abc2"

How should I write this code?

Answer 1

You are looking for a nested delayed expansion. There are several ways to achieve it. I think the simplest is this one:

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

SET arr[0]=C:\Users\me\Desktop\abc
SET arr[1]=C:\Users\me\Desktop\abc2
SET /A arrLastElement=1

CALL :subroutine %arrLastElement% arr
EXIT /B 0

:subroutine
    SET lineToExecute=FORFILES /m "*.*" /c "cmd /c echo %%dir%%"

    FOR /L %%i in (0, 1, %1) DO (
        SET dir=!%2[%%i]!
        ECHO !dir!
        call ECHO !lineToExecute!
    )

    EXIT /B 0