Excel VBA：当另一个单元格包含特定文本或字符串时，如何清除指定单元格的内容

Question

I'm having some trouble trying to find VBA code to delete multiple specific cells if a certain cell contains a specific text. This spreadsheet can run close to 100k rows as well, but will vary depending on the data pull.

The specific VBA would be able to do the following:

If Cell J3 equals #N/A, Blank, or 0, then clear contents of cells J3:K3 and P3:X3, and then repeat til it reaches the bottom of column J.

Thanks in advance

Answer 1

How to clear contents for specified cells when another cell contains specific text or string

Dim cellToClear As Range
Dim cellToCheck As Range
Dim specificText As String
If cellToCheck.Value = specificText Then cellToClear.ClearContents

"I'm having some trouble trying to find VBA code "

These links contain VBA code that you can use when you no longer have trouble trying. They contain examples you can paste into your project and modify for your needs.

This link has examples of how to read the contents of a cell .

A range is a group of one or more cells in a worksheet. You can perform an operation on a range and it will affect all the cells inside the range. This link has examples of how to work with a range .

A loop is when the program repeats the same sequence of steps, usually until a specific condition is met. You can find examples of different loops here .

Answer 2

I prefer placing values into an array if you are going to be changing a bunch of cells in a routine. This generally makes the process much quicker.

Start out by setting your worksheet and range objects. Please take note that the below code is currently using index 1 for the worksheet here: Set ws = ThisWorkbook.Worksheets(1) . If this is not the worksheet you are personally needing, then you will need to change this.

Then place the cell contents of the entire range into an array. As I mentioned earlier, this process is quicker than making adjustments to individual cells 1 at a time.

Loop the array, checking for either the specific error value #N/A or the other criteria. If this criteria is a match, you will enter another loop that quickly loops through the 'columns' in the row that will delete the values from only the columns you specified.

Once finished, rewrite the array back to the worksheet.

Sub main()

    Dim ws As Worksheet, rng As Range, dataArr() As Variant
    Set ws = ThisWorkbook.Worksheets(1)
    Set rng = ws.Range("J3:X" & ws.Cells(ws.Rows.Count, "J").End(xlUp).Row)

    ' Place the entire contents of worksheet range into an array
    dataArr = rng.Value

    Dim i As Long, x As Long, clearRow As Boolean
    For i = LBound(dataArr) To UBound(dataArr)

        If IsError(dataArr(i, 1)) Then
            If dataArr(i, 1) = CVErr(xlErrNA) Then clearRow = True
        ElseIf dataArr(i, 1) = vbNullString Or dataArr(i, 1) = 0 Then
            clearRow = True
        End If

        ' Loop thru the columns (x) of the current row (i)
        If clearRow Then
            For x = 1 To 15
                Select Case x
                Case 1, 2, 7 To 15
                    dataArr(i, x) = ""
                End Select
            Next x
            clearRow = False
        End If

    Next i

    ' Re-write the entire array back to the worksheet in one step
    rng.Value = dataArr

End Sub