Excel - 删除单元格中的特定小数

Question

I am having difficulty removing just the last decimal from my cells. Any suggestions?

Example: 0101.29.00.90 to 0101.29.0090

Answer 1

Assume A1: 0101.29.00.90

To remove the last decimal from cell, if the no of decimal does not fixed, in B1 enter formula:

=SUBSTITUTE(A1,".","",LEN(A1)-LEN(SUBSTITUTE(A1,".","")))

To remove the last decimal from cell, if the decimal fixed in 3 no, B1 formula can be shortened to:

=SUBSTITUTE(A1,".","",3)

The result is: 0101.29.0090

Answer 2

Here is a more universal approach:

Suppose your data is in cell A1 , in cell B1 enter the following array formula :

=REPLACE(A1,MAX(IFERROR(FIND(".",A1,ROW($A$1:INDEX($A:$A,LEN(A1)))),0)),1,"")

You MUST press Ctrl + Shift + Enter upon finishing the formula in the formula bar otherwise it will not function correctly. Then you can simply drag the formula down to apply across.

The logic is to use FIND function to find the position of each dot . within the string, then use MAX+IFERROR functions to return the largest value ie the position of the last dot . , then use REPLACE function to replace the last dot . with blank "" .

Here is some testing results:

| Sample Data     | Result         |
|-----------------|----------------|
| 0101.29.00.90   | 0101.29.0090   |
| 1.2.3.4.5.6.7.8 | 1.2.3.4.5.6.78 |
| 000.111.222.3   | 000.111.2223   |
| 4.3.2.01        | 4.3.201        |

Answer 3

You need to use the SUBSTITUTE function.

SUBSTITUTE(text, old_text, new_text, [instance_num])

The SUBSTITUTE function syntax has the following arguments:

Text Required . The text or the reference to a cell containing text for which you want to substitute characters.

Old_text Required . The text you want to replace.

New_text Required . The text you want to replace old_text with.

Instance_num Optional . Specifies which occurrence of old_text you want to replace with new_text. If you specify instance_num, only that instance of old_text is replaced. Otherwise, every occurrence of old_text in text is changed to new_text.

---

Last Option is not optional for your problem. For example, use the below formula

=SUBSTITUTE(A1,".","",3)

assuming that source data is in cell A1.

It will replace third dot with null string and you'll have desired solution.

ie 0101.29.00.90 to 0101.29.0090