如果单元格值等于“”，如何编写 Excel 宏以删除整行

Question

I would like to have a macro that deletes an entire row of the cell value equals "" for multiple ranges. Ranges are "B16:B115, B131:B230, B250:B349".

Logic: If cell equals "" then delete the entire row.

I want the row actually deleted and not just the contents of the cells.

Thank you.

Answer 1

This would be worth trying:

On Error Resume Next
Range("B16:B115,B131:B230,B250:B349").SpecialCells(xlCellTypeBlanks).EntireRow.Delete
On Error Goto 0

Depending on whether the "" cells have formulas or are just empty. Range.SpecialCells: What does xlCellTypeBlanks actually represent?

EDIT: if you have formulas then you have to go the long way round:

Sub DeleteEmpty()

    Dim c As Range, rngDel As Range

    For Each c In Range("B16:B115,B131:B230,B250:B349").Cells
        If Len(c.Value) = 0 Then
            If rngDel Is Nothing Then
                Set rngDel = c
            Else
                Set rngDel = Application.Union(rngDel, c)
            End If
        End If
    Next c

    If Not rngDel Is Nothing Then rngDel.EntireRow.Delete

End Sub

Answer 2

Following sub will allow you to select range to delete blank rows.

Sub RemoveBlanks()
Dim rng As Range, rws As Long, i As Long
Dim LastRow As Range
Dim myRange As Range

  Set myRange = Application.InputBox(prompt:="Select Header Cell To Remove Blanks.", Type:=8)
  'LastRow = Cells(Rows.Count, "A").End(xlUp).Row
  Set LastRow = Cells(Rows.Count, myRange.Column).End(xlUp)
  Set rng = ActiveSheet.Range(myRange.Address & ":" & LastRow.Address)
  rws = rng.Rows.Count

  For i = rws To 1 Step (-1)
    If WorksheetFunction.CountA(rng.Rows(i)) = 0 Then rng.Rows(i).EntireRow.Delete
  Next

  Set myRange = Nothing
  Set LastRow = Nothing
  Set rng = Nothing

End Sub