Haskell - 在整个列表中搜索一个字符

Question

I have following list:

 charKeys=[('1','a')
          ,('2','b')
          ,('3','c')
          ,('4','d')
          ,('5','e')]

Now i want to search for an character in the list and replicate the other character three times. I want a function like that:

 search x = if x == fst(charKeys !! 0) then replicate 3 (snd(charKeys !! 0)) else "Error" 

But this function only check the first index of the list and works only for x == '1'.

Can somebody help me, that the function also works if x == '2' or '5'?

Answer 1

There are a few ways to do this, and for all of them we will be writing a function that also takes as an input charKeys .

The most important would be using recursion:

search n charKeys = if n == fst (head charKeys) then replicate 3 (snd (head charKeys)) else search n (tail charKeys)

We can rewrite this using pattern matching and function guards like so:

search n ((k,c):lst) | k == n       = replicate 3 c
                     | otherwise    = search n lst

It's also good practice to cover all possible inputs for a pattern match, so we add this additional line:

search _ [] = error "Requested key not found"

These are pretty important concepts in Haskell, so make sure you understand what's going on here before going on.

Another solution would be to use the function find from Data.List , documented here :

import Data.List (find)

search n charKeys = case find ((==n) . fst) charKeys of
                        Just (_,c)  -> replicate 3 c
                        Nothing     -> error "Requested key not found"

Note that we're using a case statement to check whether we've found a matching element in the list, since find returns a Maybe . Also, (==n). fst (==n). fst is a more idiomatic way of saying \x -> fst x == n , using composition and operator punning.

We can simplify this even further by using Prelude's lookup function:

search n charKeys = case lookup n charKeys of
                        Just c  -> replicate 3 c
                        Nothing -> error "Requested key not found"

And even more by using maybe from Data.Maybe (also using $ ):

search n charKeys = maybe (error "Requested key not found") (replicate 3) $ lookup n charKeys