如何在 Perl 脚本中发送邮件？

Question

I have adapted a script from the Perl Cookbook. I am testing it to send mail to myself in gmail.

#!/usr/bin/perl
use strict;
use warnings;

use MIME::Lite;
my $msg;
    $msg = MIME::Lite->new(From => 'zmumba@gmail.com',
    To => 'zmumba@gmail.com',
    Subject => 'My office photo',
    Type => 'multipart/mixed');

 $msg->attach(Type => 'image/png',
         Path => '/home/zmumba/ZMD_Proj/Docs/Reporting',
         Filename => 'office_lyout.png');

$msg->attach(Type => 'TEXT',
         Data => 'I hope you can use this!');

  $msg->send( );

When I run this script, I get the message "/home/zmumba/ZMD_Proj/Docs/Reporting" not readable. From here How can I send mail through Gmail with Perl? , I now understand that I have to send mail through a mailserver to use MIME::Lite. So I replaced

$msg = MIME::Lite->new(From => 'zmumba@gmail.com

with

$msg = Email::Send::Gmail->new(From => 'zmumba@gmail.com

and I get the error "Can't locate object method "new" via package Email::Send::Gmail".

Then I tried

    $msg = Net::IMAP::Simple::SSL->new(From => 'zmumba@gmail.com',

and I get "Odd number of elements in hash assignment at /home/zmumba/perl5/lib/perl5/Net/IMAP/Simple.pm line 25. Can't call method "attach" on an undefined value at...". Any assistance on how to go about it? Thanks in anticipation.

Answer 1

The Perl Cookbook is 20 years old and its recommendations will be out of date. Using MIME::Lite is discouraged .

MIME::Lite is not recommended by its current maintainer. There are a number of alternatives, like Email::MIME or MIME::Entity and Email::Sender, which you should probably use instead. MIME::Lite continues to accrue weird bug reports, and it is not receiving a large amount of refactoring due to the availability of better alternatives. Please consider using something else.

You should probably follow their recommendation and use Email::Sender .

---

"Can't locate object method "new" via package Email::Send::Gmail"

You need to load Email::Send::Gmail with use Email::Send::Gmail .

You may need to install the Email::Send::Gmail module. It's simplest to do this using either cpanminus or install a fresh Perl with perlbrew and then use cpanminus.

---

Then I tried

$msg = Net::IMAP::Simple::SSL->new(From => 'zmumba@gmail.com',

and I get "Odd number of elements in hash assignment at /home/zmumba/perl5/lib/perl5/Net/IMAP/Simple.pm line 25.

MIME::Lite, Email::Send::Gmail, and Net::IMAP::Simple::SSL are different libraries with different interfaces that take different arguments differently. Refer to their documentation for how to use them.

Answer 2

As mentioned before, both MIME::Lite and Email::Send is discouraged -

Email::Send is going away... well, not really going away, but it's being officially marked "out of favor." It has API design problems that make it hard to usefully extend and rather than try to deprecate features and slowly ease in a new interface, we've released Email::Sender which fixes these problems and others

I have created a script which uses Email::MIME, Email::Sender::Simple, Email::Sender::Transport::SMTP for sending mail. You can take a look at https://github.com/rai-gaurav/perl-toolkit/tree/master/Mail and use it as per your requirement. Important lines from that code are -

sub create_mail {
    my ( $self, $file_attachments, $mail_subject, $mail_body ) = @_;

    my @mail_attachments;
    if (@$file_attachments) {
        foreach my $attachment (@$file_attachments) {
            my $single_attachment = Email::MIME->create(
                attributes => {
                    filename     => basename($attachment),
                    content_type => "application/json",
                    disposition  => 'attachment',
                    encoding     => 'base64',
                    name         => basename($attachment)
                },
                body => io->file($attachment)->all
            );
            push( @mail_attachments, $single_attachment );
        }
    }
    # Multipart message : It contains attachment as well as html body
    my @parts = (
        @mail_attachments,
        Email::MIME->create(
            attributes => {
                content_type => 'text/html',
                encoding     => 'quoted-printable',
                charset      => 'US-ASCII'
            },
            body_str => $mail_body,
        ),
    );

    my $mail_to_users    = join ', ', @{ $self->{config}->{mail_to} };
    my $cc_mail_to_users = join ', ', @{ $self->{config}->{mail_cc_to} };

    my $email = Email::MIME->create(
        header => [
            From    => $self->{config}->{mail_from},
            To      => $mail_to_users,
            Cc      => $cc_mail_to_users,
            Subject => $mail_subject,
        ],
        parts => [@parts],
    );
    return $email;
}

sub send_mail {
    my ( $self, $email ) = @_;
    my $transport = Email::Sender::Transport::SMTP->new(
        {
            host => $self->{config}->{smtp_server}
        }
    );
    eval { sendmail( $email, { transport => $transport } ); };
    if ($@) {
        return 0, $@;
    }
    else {
        return 1;
    }
}

Answer 3

Gmail and other mail servers will not allow unauthorized relay. In most cases you will need authorized access.

Here is what I use, after also trying many modules. Maybe this solution seems a little bit overdone, but it's easy to change for HTML with plain text as alternative or other attachments. Parameters of the transport are the most common ones.

#!perl

use strict;
use warnings;
use utf8;

use Email::Sender::Simple qw(sendmail try_to_sendmail);
use Email::Sender::Transport::SMTPS;
use Email::Simple ();
use Email::Simple::Creator ();
use Email::MIME;

send_my_mail('john.doe@hisdomain.com','Test','Test, pls ignore');

sub send_my_mail {
  my ($to_mail_address, $subject, $body_text) = @_;

  my $smtpserver   = 'smtp.mydomain.com';
  my $smtpport     = 587;
  my $smtpuser     = 'me@mydomain.com';
  my $smtppassword = 'mysecret';

  my $transport = Email::Sender::Transport::SMTPS->new({
    host          => $smtpserver,
    ssl           => 'starttls',
    port          => $smtpport,
    sasl_username => $smtpuser,
    sasl_password => $smtppassword,
    #debug => 1,
  });

  my $text_part = Email::MIME->create(
    attributes => {
        'encoding'     => 'quoted-printable',
        'content_type' => 'text/plain',
        'charset'      => 'UTF-8',
    },
    'body_str' => $body_text,
  );

  my $alternative_part = Email::MIME->create(
    attributes => {
        'content_type' => 'multipart/alternative',
    },
    parts => [ $text_part, ],
  );

  my $email = Email::MIME->create(
    header_str => [
        To      => $to_mail_address,
        From    => "Website <$smtpuser>",
        Subject => $subject,
    ],
    attributes => {
             'content_type' => 'multipart/mixed',
         },
    parts => [  $alternative_part   ],
  );

  my $status = try_to_sendmail($email, { transport => $transport });

  return $status;
}

Answer 4

Take a look at Email::Send::Gmail module. It might solve your problem.