如何在数组中获取存储过程 output 值

Question

I am creating one procedure regarding getting the output value. The output value are called in another procedure and store in an array.

procedure get_value_temp
(
v_name_id in out varchar2,
v_event_id out  varchar2
)
is
begin  
             select s.name_id,d.event_id into v_name_id ,v_event_id from aokk_kala_appreg_stage s inner join aokk_kala_appreg_det d
            on s.name_id=d.name_id where s.name_id=v_name_id;
            --return;
 end;

The following is another procedure.

 declare
 V_ARRAY            MYTABLETYPE;
name_id  varchar2(100);
 BEGIN
V_ARRAY:=get_value_temp(220);--get output value and store in array.
 FOR I IN V_ARRAY.FIRST .. V_ARRAY.LAST
                    loop
                        dbms_output.put_line(V_ARRAY(I));
                    END LOOP;

end;

Please help me with how to get stored procedure output value in the array.

Answer 1

For example, say you have this table:

create table myTab(n number, v varchar2(100));
insert into myTab(n, v) values (1, 'one');
insert into myTab(n, v) values (2, 'two');
insert into myTab(n, v) values (2, 'TWO');

You can build a procedure like:

create or replace procedure myProc (p_n IN number, po_mytabletype OUT mytabletype) is    
begin
    select v
    bulk collect into po_mytabletype
    from myTab
    where n = p_n;
end;

If you call it this way:

declare
    v_mytabletype    mytabletype;
begin
    myProc(2, v_mytabletype);
    for i in v_mytabletype.first .. v_mytabletype.last loop
        dbms_output.put_line (v_mytabletype(i));
    end loop;
end; 

you get:

two
TWO

Answer 2

This is sample code demonstration as per my understanding of your requirement, please share some more details if it is not as per your requirement.

CREATE OR REPLACE PROCEDURE get_value_temp(v_name_id IN VARCHAR2, 
                                           o_events_for_nameid OUT sys_refcursor) IS
BEGIN 
  open o_events_for_nameid 
   for select s.event_id from 
  (SELECT 'A' name_id, '1' event_id FROM dual UNION 
   SELECT 'A' name_id, '2' event_id FROM dual UNION 
   SELECT 'C' name_id, ' 3' event_id FROM dual UNION 
   SELECT 'D' name_id, '4' event_id FROM dual UNION
   SELECT 'D' name_id, '5' event_id FROM dual UNION 
   SELECT 'E' name_id, '6' event_id FROM dual) s WHERE s.name_id = v_name_id;
   END;
   / 

drop type mytabletype;
/
CREATE OR REPLACE TYPE mytabletype AS TABLE OF VARCHAR2(200); -- this is nested table definition 
/

Now test the code...

DECLARE
  v_nested_table             mytabletype :=  mytabletype();
  o_events_for_nameid        SYS_REFCURSOR;

BEGIN
  get_value_temp(v_name_id           => 'A',
                 o_events_for_nameid => o_events_for_nameid);

    FETCH o_events_for_nameid BULK COLLECT
      INTO v_nested_table;               
  FOR i IN v_nested_table.first .. v_nested_table.last
  LOOP
    dbms_output.put_line(v_nested_table(i));
  END LOOP;
END;