如何创建 XSLT 以基于两个 XML 文档之间的兄弟节点文本匹配来合并两个文档？

Question

I'm asking for some assistance with the following problem. I'm trying to create an XSLT that will ultimately merge the contents between Main.xml & Main_2.xml. These are contrived examples but the structure is correct. The goal is simply to replace any 'fff' and 'zzz' elements from Main.xml with 'ggg' elements and its children from Main_2.xml if their 'ccc' siblings match in both Main.xml and Main_2.xml. The rest of Main.xml must be left unchanged. Any pointers or references are appreciated.

Main.xml

<aaa>
    <bbb>
        <ccc>1234</ccc>
        <ddd>apple</ddd>
        <eeee>oranges</eeee>
        <fff>bananas</fff>
    </bbb>
    <bbb>
        <ccc>9876</ccc>
        <ddd>pears</ddd>
        <eeee>watermelon</eeee>
        <zzz>grapes</zzz>
    </bbb>
</aaa>

Main_2.xml

<aaa>
    <bbb>
        <ccc>1234</ccc>
        <ddd>apple</ddd>
        <eeee>oranges</eeee>
        <ggg>
            <hhh>asdf</hhh>
            <iii>
                <jjj>blue</jjj>
                <kkk>red</kkk>
                <lll>green</lll>
            </iii>
        </ggg>
    </bbb>
    <bbb>
        <ccc>9876</ccc>
        <ddd>pears</ddd>
        <eeee>watermelon</eeee>
        <ggg>
            <hhh>fdsa</hhh>
            <iii>
                <jjj>purple</jjj>
                <kkk>yellow</kkk>
                <lll>white</lll>
            </iii>
        </ggg>
    </bbb>
    <bbb>
        <ccc>45678</ccc>
        <ddd>veggies</ddd>
        <eeee>carrots</eeee>
        <ggg>
            <hhh>zxcf</hhh>
            <iii>
                <jjj>cyan</jjj>
                <kkk>black</kkk>
            </iii>
        </ggg>
    </bbb>
</aaa>

Desired output

<aaa>
    <bbb>
        <ccc>1234</ccc>
        <ddd>apple</ddd>
        <eeee>oranges</eeee>
        <ggg>
            <hhh>asdf</hhh>
            <iii>
                <jjj>blue</jjj>
                <kkk>red</kkk>
                <lll>green</lll>
            </iii>
        </ggg>
    </bbb>
    <bbb>
        <ccc>9876</ccc>
        <ddd>pears</ddd>
        <eeee>watermelon</eeee>
        <ggg>
            <hhh>fdsa</hhh>
            <iii>
                <jjj>purple</jjj>
                <kkk>yellow</kkk>
                <lll>white</lll>
            </iii>
        </ggg>
    </bbb>
</aaa>

Current XSLT

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance">

    <xsl:output method="xml" indent="yes" version="1.0" encoding="utf-8" />

    <xsl:variable name="tempMain" select="document('Main_2.xml')"/>

<!-- attempt at using key, didn't pan out
    <xsl:key name="fruits" match="bbb" use="ccc"/>
-->

    <!-- General copy -->
    <xsl:template match="@* | node()">
        <xsl:copy>
            <xsl:apply-templates select="@* | node()" />
        </xsl:copy>
    </xsl:template>


    <!-- Replace these fields with new ones -->
    <xsl:template match="fff | zzz">
        <xsl:copy-of select="$tempMain/aaa/bbb[ccc = current()../ccc]/ggg"/>

    </xsl:template>  -->

</xsl:stylesheet>

As a side question that's not entirely related, what resources would you recommend when creating XSLTs? I've gone through the tutorial on w3schools, which isn't the greatest. I feel like I'm just copying bits and pieces from different questions and seeing what works but would rather improve my knowledge.

Edit The answer by michael.hor257k works, I just need to modify it so that it doesn't remove fff or zzz elements if ccc text isn't found in Main_2.xml

Answer 1

Try it this way?

XSLT 1.0

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
<xsl:strip-space elements="*"/>

<xsl:param name="path-to-lookup"> Main_2.xml</xsl:param>
<xsl:key name="fruits" match="bbb" use="ccc"/>

<!-- identity transform -->
<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="fff | zzz">
    <xsl:variable name="key" select="../ccc"/>
    <!-- switch context to use key -->
    <xsl:for-each select="document($path-to-lookup)">
        <xsl:apply-templates select="key('fruits', $key)/ggg"/>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

---

Added:

how could I modify it to not delete fff or zzz elements if the text from ccc in Main.xml doesn't match a ccc element from Main_2.xml?

In such case I might give up on the use of key, and do:

<xsl:template match="fff | zzz">
    <xsl:variable name="lookup" select="document($path-to-lookup)/aaa/bbb[ccc=current()/../ccc]"/>
    <xsl:choose>
        <xsl:when test="$lookup">
            <xsl:copy-of select="$lookup/ggg"/>
        </xsl:when>
        <xsl:otherwise>
            <xsl:copy-of select="."/>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>