Excel - 在公式中使用 2 个或更多标准对数据进行排序（从小到大）？

Question

I am trying to find result of sort data in table with specific criteria

for example:

yellow is ALL-JOB fill by user RED is unfinished JOB sort by "START DATE" Green is completed JOB sort by "END DATE" and "JOB ID"

i need to sorting data in yellow table and show result in red/green table,smallest to largest

Any help would be greatly appreciated. Thank you so much in advance.

ps.My English is not good. Please forgive me if I make grammatical mistakes.

Answer 1

With the new Dynamic Array Functions(Currently only available to Office 365 Insiders) a couple formula will do what you want quickly:

First for the Red data, In G3 put:

=SORTBY(FILTER(B3:D100,(D3:D100="")*(B3:B100<>""),""),FILTER(B3:B100,(D3:D100="")*(B3:B100<>""),""))

Then in F3 put:

=SEQUENCE(ROWS(G3#))

In L3:

=SORTBY(FILTER(B3:D100,(D3:D100<>"")*(B3:B100<>""),""),FILTER(D3:D100,(D3:D100<>"")*(B3:B100<>""),""),1,FILTER(C3:C100,(D3:D100<>"")*(B3:B100<>""),""),-1)

and in K3:

=SEQUENCE(ROWS(L3#))

And Excel will spill the data accordingly without the need to copy paste formula into all the cells.

---

Without the dynamic array functions we need to resort to INDEX/AGGREGATE and only one sort, the second adds too much to the function.

Start by sorting the original data by the Job number then use the following

In G3 put:

=IFERROR(INDEX(B:B,AGGREGATE(15,7,ROW($B$3:$B$17)/((AGGREGATE(15,7,$B$3:$B$17/(($D$3:$D$17="")*(COUNTIFS($H$2:$H2,$B$3:$B$17)=0)),ROW($ZZ1))=$B$3:$B$17)*($D$3:$D$17="")*(COUNTIFS($H$2:$H2,$C$3:$C$17)=0)),1)),"")

Copy over and down the range. Then in F3 Put:

=IF(G3<>"",ROW($ZZ1),"")

Then copy down the range

for the other, Put this in L3:

=IFERROR(INDEX(B:B,AGGREGATE(15,7,ROW($B$3:$B$17)/((AGGREGATE(15,7,$D$3:$D$17/(($D$3:$D$17<>"")*(COUNTIFS($H$2:$H2,$B$3:$B$17)=0)),ROW($ZZ1))=$D$3:$D$17)*($D$3:$D$17<>"")*(COUNTIFS($H$2:$H2,$C$3:$C$17)=0)),1)),"")

And copy over and down the range. Then in K3 put

=IF(L3<>"",ROW($ZZ1),"")

Copy down the range.

---

With both you will need to format the output cells with the number format desired.