VB6 ADODB.Recordset Record.Count 不起作用/EOF 和 BOF 不可用

Question

I've got a question regarding ADODB recordset in VB6, which has confused me for a few weeks. I've written the recordset into worksheets to achieve some results that I can't get from recordset directly. But as the data set builds up, writing the recordset into worksheet would slow the program down, I wonder if someone could resolve the recordset puzzle for me.

Below is the problem I have - 1) xRst.Recordcount always returns -1 2) Error message, "Arguments are of the wrong type, are out of acceptable range, or are in conflict with one another", pops up on set (A).cursorlocation to either adUseClient or adUseServer, and (B).LockType 3) Unable to.getrows on recordset => I believe it's the same cause as xRst.Recordcount returning -1?

Below is part of my code. Could above issues caused by limitation of the provider?

xConnstring = "Provider=Microsoft.ACE.OLEDB.12.0; Extended Properties='Excel 12.0'; Data Source =" & Thisworkbook.fullname
xCnn.Open xConnstring
xSqlstring = " SELECT * FROM [APRI$] "
Set xRst = xCnn.Execute(xSqlstring)
Msgbox(xRst.RecordCount)
Do Until xRst.EOF
     ......
     xRst.MoveNext
Loop

For the recordset, I've also tried two open methods, but doesn't work either.

Set xRst.ActiveConnection = xCnn
xRst.Source = xSqlstring
xRst.CursorType = adOpenDynamic
------Error Message Occurs On Below Two Lines------
xRst.CursorLocation = adUseServer
xRst.LockType = adLockOptimistic
xRst.Open

Below code will encounter an error, but it will pass through when the two last parameters are removed

xRst.Open xSqlstring, xCnn, adOpenKeyset, adUseServer, adLockoptimistic

Could someone please kindly advise how I can get the 1) recordset.recordcount, 2) recordset.movenext work?

Thanks heaps in advance.

Answer 1

Default cursortype is adOpenForwardOnly. With adOpenForwardOnly or adOpenUnspecified the record count is always returned as -1. Use either adOpenKeySet or adOpenStatic. ie: (I assume sheet name APRI is correct and not APRIL - and there is a worksheet named Dummy to list the results for test):

Dim xCnn As ADODB.Connection
Dim xRst As ADODB.Recordset
Dim xConnString As String

xConnString = "Provider=Microsoft.ACE.OLEDB.12.0; Extended Properties='Excel 12.0'; Data Source =" & ThisWorkbook.FullName
Set xCnn = New ADODB.Connection
xCnn.Open xConnString
xSqlstring = " SELECT * FROM [APRI$] "
Set xRst = New ADODB.Recordset
xRst.Open xSqlstring, xCnn, adOpenStatic
MsgBox (xRst.RecordCount)
Dim row As Integer
row = 1
Dim ws As Worksheet
Set ws = ThisWorkbook.Worksheets("Dummy")
Do Until xRst.EOF
    '...
    ws.Cells(row, 1).Value = xRst.Fields(0).Value
    row = row + 1
     xRst.MoveNext
Loop