如果在一起，如何将两者结合起来

Question

I have a script that run on the list of files to do some of the changes, each file of them has a call event and the call event details contains 4 elements so i just want to do the changes on 2 of them only here I'm stuck with how to combine two next if in one loop, here I have used 2 loops to do the job but it takes more time , is there any idea about how to do that ?

my $calleventtag = $struct->{'transferBatch'}->{'callEventDetails'};
my @indexes = reverse (grep { exists $calleventtag->[$_]->{'supplServiceEvent'} } 0..$#$calleventtag);

    my $sup_event_cnt = $#indexes;

    foreach my $index (@indexes)
    {
    splice (@$calleventtag , $index,1);
    }
foreach (0..$#$calleventtag)
    {
    next if ( ! exists $calleventtag->[$_]->{'mobileOriginatedCall'}) ;

        if ( exists $calleventtag->[$_]->{'mobileOriginatedCall'}->{'basicCallInformation'}->{'destinationNetwork'} )
        {
            delete $calleventtag->[$_]->{'mobileOriginatedCall'}->{'basicCallInformation'}->{'destinationNetwork'};
        }

        if ( exists $calleventtag->[$_]->{'mobileOriginatedCall'}->{'basicCallInformation'}->{'chargeableSubscriber'}->{'simChargeableSubscriber'}->{'msisdn'} 
        && $calleventtag->[$_]->{'mobileOriginatedCall'}->{'basicCallInformation'}->{'chargeableSubscriber'}->{'simChargeableSubscriber'}->{'msisdn'} !~ m/^96279/ 
        )
        {
            delete $calleventtag->[$_]->{'mobileOriginatedCall'}->{'basicCallInformation'}->{'chargeableSubscriber'}->{'simChargeableSubscriber'}->{'msisdn'};
        }

    }
foreach (0..$#$calleventtag)
    {
next if ( ! exists $calleventtag->[$_]->{'gprsCall'});

    if ( exists $calleventtag->[$_]->{'gprsCall'}->{'gprsBasicCallInformation'}->{'gprsDestination'}->{'accessPointNameOI'} )
            {
                delete $calleventtag->[$_]->{'gprsCall'}->{'gprsBasicCallInformation'}->{'gprsDestination'}->{'accessPointNameOI'};
            }
    }

Answer 1

for (...) {
   next if ...;

   ...
}

can also be written as

for (...) {
   if (!...) {
      ...
   }
}

You could use the following:

use Data::Diver qw( Dive );

my $call_event_details = Dive($struct, qw( transferBatch callEventDetails ));

for my $call_event_detail (@$call_event_details) {
   next if !$call_event_detail->{supplServiceEvent};

   if ( my $bci = Dive($call_event_detail, qw( mobileOriginatedCall basicCallInformation )) ) {
      delete $bci->{destinationNetwork};

      if ( my $scs = $bci->{simChargeableSubscriber} ) {
         my $msisdc = $scs->{msisdn};
         delete $scs->{msisdn} if $msisdc && $msisdc !~ /^96279/;
      }
   }

   if ( my $dest = Dive($call_event_detail, qw( gprsCall gprsBasicCallInformation gprsDestination )) ) {
      delete $dest->{accessPointNameOI};
   }
}

Notes:

• The quotes around string literals aren't needed in hash indexes if the string is valid valid identifier. For example, $hash->{'foo'} can be written as $hash->{foo} .
• -> isn't needed between two indexes. For example, $hash->{foo}->{bar} can be written as $hash->{foo}{bar} .
• If a hash element is either a reference or doesn't exist, you don't need to use exists to check if you have a reference; you can use a simple truth test since references are always true.

• [BUG FIX] $hash->{foo}{bar} can autovivify $hash->{foo} (cause a reference to be assigned to it), so your tests to check if stuff exists could actually be causing things to be created. To fix this, you can replace

  if ($hash->{foo}{bar})

  with

  if ($hash->{foo} && $hash->{foo}{bar})

  or

  if (Dive($hash, qw( foo bar )))

• Using the same long chain of indexes ( ->{foo}{bar}{baz} ) repeatedly is error prone.

• It's best to use plural names for arrays. First, it's more descriptive, but it also makes choosing names for loop variables easier.
• Speaking of variable names, why would use $calleventtag for the name of the variable containing callEventDetails nodes?
• You don't need to check if a hash element exists before trying to delete it; delete can be passed an element that doesn't exist.
• No need to loop over the indexes of an array if you don't need the indexes.
• grep was a good choice, but splice was not. You should have used: $calleventtag = [ grep { ... } @$calleventtag ]; . I moved the check into the loop.