在所有子目录中显示具有相同文件名的多个 .txt 文件的内容

Question

I have multiple files with the same filename under various subdirectories, for example:

c:\kjhsd\client.txt
c:\ekjjs\client.txt
c:\oiwnk\client.txt

I do not know the middle part of the path represented by random letters above, but the filename is always consistent.

I need a way to use this command: type client.txt (or) more client.txt but to display the content of all text files with the filename "client.txt" under any directory at the same time.

So if:

c:\\kjhsd\\client.txt contained: hello

c:\\ekjjs\\client.txt contained: helloworld

c:\\oiwnk\\client.txt contained: helloagain

After running the single command, I would see:

hello
helloworld
helloagain

Thanks in advance :)

Answer 1

from cmd.exe :

@for /r c:\ %a in ("client.txt") do @type "%~a"2>nul

From a Batch-File :

@for /r c:\ %%a in ("client.txt") do @type "%%~a"2>nul

Edit: as per the newline requirement:

@echo off
Pushd "c:\somedir"
for /f %%a in ('dir /b /s /a-d ^| find /i "client.txt"') do (
    type "%%~a"2>nul
    echo(
)
Popd

or if you want to see which file had what text:

@echo off
Pushd "c:\somedir"
for /f %%a in ('dir /b /s /a-d ^| find /i "client.txt"') do (
    echo content: "%%~a"
    type "%%~a"2>nul
    echo(
)
Popd

Answer 2

The easiest approach is to use a for /D loop to find the different directories, and to let find /V "" return the contents of the files, because then a line-break is automatically appended to every file in case there is none in the file itself (opposed to type ).

In Command Prompt do this:

@for /D %I in ("D:\some\root\*") do @(< "%~I\client.txt" find /V "") 2> nul

In a batch file do this:

@for /D %%I in ("D:\some\root\*") do @(< "%%~I\client.txt" find /V "") 2> nul

The 2> nul portion suppresses eerror messages if a directory does not contain a file called client.txt .