更改列中所有单元格的值

Question

I need to write code that reformats text messages in an excel file using VBA. One column has the dates each text was sent/received. I need to change this column to say "Day 1", "Day 2", instead. So for example, 11/3/19 would be "Day 1" 11/3/19 would be "Day 1" 11/4/19 would be "Day 2" 11/6/19 would be "Day 4"

To do this, I want to subtract each date by the first date and add 1. I can do this per individual cell:

Sub Days()
Range("M2").Value = "Day " + CStr(Range("E2").Value - Range("E2").Value + 1)
Range("M3").Value = "Day " + CStr(Range("E3").Value - Range("E2").Value + 1)
Range("M4").Value = "Day " + CStr(Range("E4").Value - Range("E2").Value + 1)
End Sub

I want it done to every cell in column E. This was my attempt:

Sub Days()
Columns("M:M").Value = "Day " + CStr(Columns("E:E").Value - Range("E2").Value + 1)
(End Sub)

How would I adjust the code to make it work?

Answer 1

If you really want this to be VBA, here's one solution, leveraging the formula already provided in comments:

Sub Days()
    With ActiveSheet
        Dim lastRow As Long
        lastRow = .Cells(.Rows.Count, "E").End(xlUp).Row

        .Range("M2:M" & lastRow).Formula = "=""Day "" & E2 - $E$2 + 1"
        .Range("M2:M" & lastRow).Value = .Range("M2:M" & lastRow).Value
    End With
End Sub

Answer 2

Do not do the full column. Find the last cell with data in column E then use Evaluate:

Sub Days()
    With Worksheets("Sheet2")
        Dim lstRow As Long
        lstRow = .Cells(.Rows.Count, 5).End(xlUp).Row

        .Range("M2:M" & lstRow) = .Evaluate("INDEX(""Day "" & E2:E" & lstRow & " - E2 + 1,)")
    End With
End Sub