借助 xslt 合并多个 xml 文件

Question

List of Input files will be passed to XSLT from java code. I am using tokenizer to split the input files and get coordinator nodes from all input files and append into resultant file

<xsl:param name="listOfFiles"/>


<xsl:template match="/*">
        <xsl:for-each select="tokenize($listOfFiles, ',')">
            <xsl:variable name="fileName" select="."/>
            <xsl:variable name="updates" select="document($fileName)" />
            <xsl:variable name="updateItems" select="$updates/bundle-app/coordinator" />
                <xsl:copy>
                    <xsl:apply-templates select="$updateItems" />
                </xsl:copy>
        </xsl:for-each>
</xsl:template>

My result file just prints the file names passed to listOfFiles instead of coordinator nodes in the files. Working XSLT with one file

<xsl:param name="discoveryFile"/>
<xsl:param name="updates" select="document($discoveryFile)" />
<xsl:variable name="updateItems" select="$updates/bundle-app/coordinator" />
<xsl:template match="@* | node()">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="/*">
    <xsl:copy>
        <xsl:apply-templates select="@* | node()[not(self::coordinator)] |
                               coordinator[not(id = $updateItems/id)]" />
        <xsl:apply-templates select="$updateItems" />
    </xsl:copy>
</xsl:template>

I am very new to XSLT Please suggest a way to proceed with the list of files.

Answer 1

Within an xsl:for-each instruction, the context item is set to each member of the selected sequence in turn. Importantly, your xsl:for-each is selecting a sequence of string values . This is perfectly acceptable, but it does mean that within your xsl:for-each , the context item will be a string value. This has an important effect on the behavior of the xsl:copy instruction you're using.

xsl:copy will copy whatever the current context item is, so it is copying each of your tokenized file names to the output, as you observed. However, xsl:copy is allowed to contain a sequence constructor , as yours does:

<xsl:copy>
  <!-- The instructions here within the xsl:copy element are a sequence constructor -->
  <xsl:apply-templates select="$updateItems" />
</xsl:copy>

The issue is that a sequence constructor within xsl:copy is only used if the context item is an element or a document node (see section 7.5 of the XSLT 1.0 spec ). Since the context item in this case is an string value, nothing is done with the result of the xsl:apply-templates instruction. (In fact, the processor may not even be evaluating this instruction since it can tell it will have no effect on the output.)

It seems you really just want to apply templates to the nodes you've selected from each file, not copy the context item at any point. So this is probably what you want:

<xsl:param name="listOfFiles"/>

<xsl:template match="/*">
  <xsl:for-each select="tokenize($listOfFiles, ',')">
    <xsl:variable name="fileName" select="."/>
    <xsl:variable name="updates" select="document($fileName)" />
    <xsl:variable name="updateItems" select="$updates/bundle-app/coordinator" />
    <xsl:apply-templates select="$updateItems" />
  </xsl:for-each>
</xsl:template>

This assumes you have either an identity template defined in your stylesheet, or some other templates meant to further process the coordinator elements. If your intent is really just to merge them unchanged into an aggregate document, then you could replace <xsl:apply-templates select="$updateItems" /> with <xsl:copy-of select="$updateItems" /> .

Answer 2

XSLT file that worked for my requirement

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>


    <xsl:param name="tempFiles"/>

    <xsl:template match="/">
        <xsl:copy>
            <xsl:apply-templates mode="rootcopy"/>
        </xsl:copy>
    </xsl:template>

    <!-- Deep copy template -->
    <xsl:template match="@* | node()" mode="copy">
        <xsl:copy>
            <xsl:apply-templates mode="copy" select="@*"/>
            <xsl:apply-templates mode="copy"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="/*" mode="rootcopy">
        <xsl:copy>
            <xsl:apply-templates mode="copy" select="/bundle-app/*"/>
            <xsl:for-each select="tokenize($tempFiles, ',')">
                <xsl:variable name="fileName" select="."/>
                <xsl:variable name="updates" select="document($fileName)" />
                <xsl:variable name="updateItems" select="$updates/bundle-app/*" />
                <xsl:apply-templates mode="copy" select="$updateItems"/>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>