如何使用 CMake 为 Visual Studio 解决方案设置程序集引用？

Question

I'm working with C code where the production compiler and CI runs in Linux but the development environment is Windows and VS. The test framework used is NUnit, which is written in C# and imported as a DLL via Nuget.

I'm used to C and writing target oriented CMake but VS solutions and .NET is unknown territory for me and the weird mix of C and C# doesn't make things easier. To complicate things further there is a tool generating a mock for the platform code which the C code is to run on (I think the platform Mock is written in C++).

So, I'm using CMake 3.15.3 and Visual Studio 2017, and the setup I need to get working is the following. A top CMakeLists.txt like:

cmake_minimum_required(VERSION 3.3) 
project(MyApplication)

include(SUTWrapper)

add_subdirectory(source)
add_subdirectory(suttest)

A CMakeLists.txt in ./source/ like:

find_package(PlatformInterface)

add_library(${CMAKE_PROJECT_NAME} STATIC
    MyApplication.c)

target_link_libraries(${CMAKE_PROJECT_NAME}
    PUBLIC
        PlatformInterface)

A CmakeLists.txt in ./suttest/ like:

enable_language(CSharp)

add_executable(${CMAKE_PROJECT_NAME}_tests
    MyApplication_suite1.cs
    Program.cs
    TestUtils.cs)

add_sut_wrapper()

add_test(
    NAME
        Test${CMAKE_PROJECT_NAME}
    COMMAND
        MyApplication_tests.exe
    CONFIGURATIONS
        Debug)

And in the cmake folder containing all the CMake modules, the file SUTWrapper.cmake:

function(add_sut_wrapper)
    set(PATH_TO_WRAPPER path/to/wrapper/here)
    add_library(${CMAKE_PROJECT_NAME}_wrapper STATIC
        ${PATH_TO_WRAPPER}/foo.cs
        ${PATH_TO_WRAPPER}/bar.cs
        ${PATH_TO_WRAPPER}/baz.cs)

    set_property(
        TARGET ${CMAKE_PROJECT_NAME}_wrapper
        PROPERTY
        VS_DOTNET_REFERENCES "System")

    set_property(
        TARGET ${CMAKE_PROJECT_NAME}_tests
        PROPERTY
            VS_PACKAGE_REFERENCES "NUnit_3.7.1;NUnitLite_3.7.2")

    set(PATH_TO_PLATFORM_MOCK path/to/PlatformMock/here/)
    add_library(${CMAKE_PROJECT_NAME}_Platform_Mock STATIC
        ${PATH_TO_PLATFORM_MOCK}/Swc_${CMAKE_PROJECT_NAME}.cpp)

    add_library(${CMAKE_PROJECT_NAME}_shared SHARED
        ../source/MyApplication.c)

    target_link_libraries(${CMAKE_PROJECT_NAME}_shared
        PUBLIC
            PlatformInterface
            ${CMAKE_PROJECT_NAME}_Platform_Mock)

    target_link_libraries(${CMAKE_PROJECT_NAME}_tests
        PUBLIC
            ${CMAKE_PROJECT_NAME}_shared)

endfunction()

Then there is another file in the cmake folder, FindPlatformInterface.cmake:

add_library(PlatformInterface INTERFACE)

target_include_directories(PlatformInterface 
    INTERFACE
        path/to/PlatformInterface/headers/here
        path/to/more/PlatformInterface/headers/here)

The unorthodox use of find_package for PlatformInterface is a temporary work around and the add_sut_wrapper function is a way to handle that a whole mountain of wrapper code is already generated before this CMake project is built. I'm working with plenty of legacy forcing some odd work arounds, sorry for the weirdness.

As I understand it the NUnit setup expects the test to be built as an executable linking to a DLL of the Application code (which in turn is linked with the PlatformInterface, PlatformMock).

This all generates a VS solution when running CMake, without any warnings, but when I try to build the solution in VS I get this error:

Error CS0246 The type or namespace name 'Vector' could not be found (are you missing a using directive or an assembly reference?) MyApplication_tests

Vector is a namespace in the static library called MyApplication_wrapper. So obviously I link the code containing Vector. I got a similar problem before, with the namespace System and with linking to NUnit, I solved that by adding

set_property(
    TARGET ${CMAKE_PROJECT_NAME}_wrapper
    PROPERTY
    VS_DOTNET_REFERENCES "System")

set_property(
    TARGET ${CMAKE_PROJECT_NAME}_tests
    PROPERTY
        VS_PACKAGE_REFERENCES "NUnit_3.7.1;NUnitLite_3.7.2")

to the function add_sut_wrapper. I just can't figure out how to add the assembly reference for Vector.

I'v had to obfuscate the names and paths a bit and I tried to remove some irrelevant details but I think the essentials are there.

Answer 1

If you want the Vector namespace to be accessible from your MyApplication_tests target, you have to link the wrapper library containing Vector to that target. Try changing your target_link_libraries() call to include MyApplication_tests .

Also, using STATIC C# targets in CMake is discouraged, and is not guaranteed to be supported in the future. The C# terminology doesn't really use the "static" and "shared" library terms used in C/C++; rather, "netmodule" and "assembly" are typically used (see this blog post ). You should use assemblies ( SHARED ) when defining C# libraries using CMake:

add_library(${CMAKE_PROJECT_NAME}_wrapper SHARED
    ${PATH_TO_WRAPPER}/foo.cs
    ${PATH_TO_WRAPPER}/bar.cs
    ${PATH_TO_WRAPPER}/baz.cs)    

...

target_link_libraries(${CMAKE_PROJECT_NAME}_tests
    PUBLIC
        ${CMAKE_PROJECT_NAME}_wrapper
        ${CMAKE_PROJECT_NAME}_shared)