macOS 终端（或 AppleScript） - 从 Dock 中删除文件夹

Question

I have a folder on the right side of the Dock that I'd like to be able to remove via the command line (which I will ultimately add into an AppleScript script).

Is there a command line utility for removing a folder from the Dock?

Edit: I found this script, which removes a folder titled "Airdrop" from my dock by right-clicking on it, clicking Options , and then clicking Remove from Dock

tell application "System Events" to tell UI element "AirDrop" of list 1 of application process "Dock"
    perform action "AXShowMenu"
    click menu item "Options" of menu 1
    click menu item "Remove from Dock" of menu 1 of menu item "Options" of menu 1
end tell

However, because it uses UI scripting, the rick-click menu appears as shown in the image below, when the script is run.

Is there someway to prevent this menu from showing up on my screen when I run the script?

Answer 1

The script below can remove a named folder's dock tile from the dock. Currently, it is set to remove the Downloads folder's dock tile, provided there is one.

use framework "Foundation"
use framework "AppKit"

property this : a reference to the current application

property NSArray : a reference to NSArray of this
property NSMutableDictionary : a reference to NSMutableDictionary of this
property NSPredicate : a reference to NSPredicate of this
property NSPropertyList : a reference to NSPropertyListSerialization of this
property NSRunningApplication : a reference to NSRunningApplication of this
property NSString : a reference to NSString of this

property BinaryPList : 200

property id : "com.apple.dock"
property file : "~/Library/Preferences/" & id & ".plist"
property key : "persistent-others"
property keys : [key, "tile-data", "file-label", "lowercaseString"]


removeDockTileFolder("Downloads")
if the result = true then return killDock()
false


to removeDockTileFolder(directory as text)
    local directory

    set filepath to (NSString's ¬
        stringWithString:(my file))'s ¬
        stringByStandardizingPath()

    tell (NSMutableDictionary's dictionaryWithContentsOfFile:filepath)
        tell valueForKeyPath_((NSArray's ¬
            arrayWithArray:(keys as list))'s ¬
            componentsJoinedByString:".")
            set N to |count|()
            set i to indexOfObject_((NSString's ¬
                stringWithString:directory)'s ¬
                lowercaseString())
            if i ≥ N then return false
        end tell

        valueForKey_(my key)'s removeObjectAtIndex:i

        tell (NSPropertyList's dataFromPropertyList:it ¬
            format:BinaryPList errorDescription:(missing value)) ¬
            to writeToFile:filepath atomically:yes
    end tell
end removeDockTileForFolder

to killDock()
    (runningApplicationsWithBundleIdentifier_(my id) ¬
        in the NSRunningApplication)'s terminate

    true
end killDock

Returns true upon success; false upon failure (the supplied name did not match the name of any of the folder dock tiles).