如何使用从 txt 文件中读取的变量使用批处理来输出文本块？

Question

TIA for any help or advice.

I have a requirement to import over 10k connection strings into MTPuTTY and the only way to do so is via the import function using an xml.

I have a connectionstrings.txt which has a list of all the strings and I'll be using each value as an entry several times in each block of text.

So the strings.txt file would look like;

username1@servername1 username1@servername2 username2@servername1 username2@servername2 etc

The batch file should take each of these as a variable and enter them into the block before outputting the block to an xml.

The standard block should look like this;

<Node Type="1">
            <SavedSession>username1@servername1 <SavedSession>
            <DisplayName>username1@servername1 </DisplayName>
            <ServerName>username1@servername1 </ServerName>
            <PuttyConType>0</PuttyConType>
            <Port>22</Port>
            <UserName></UserName>
            <Password></Password>
            <PasswordDelay>0</PasswordDelay>
            <CLParams>-load username1@servername1  "username1@servername1 " -P 22</CLParams>
            <ScriptDelay>0</ScriptDelay> ) 

So far I've tried to compile an IF statement using %%I as the variable and building the block with that but I get various errors such as Echo not expected. I assume I'm being daft and missing basic syntax.

FOR /F %%i in (connection strings.txt) echo ( 

 <Node Type="1">
            <SavedSession>%%i</SavedSession>
            <DisplayName>%%i</DisplayName>
            <ServerName>%%i</ServerName>
            <PuttyConType>0</PuttyConType>
            <Port>22</Port>
            <UserName></UserName>
            <Password></Password>
            <PasswordDelay>0</PasswordDelay>
            <CLParams>-load %%i "%%i" -P 22</CLParams>
            <ScriptDelay>0</ScriptDelay> ) >> connection strings.xml

Ideally, it'd be great if the batch could generate separate XML files per user if that's possible?

Answer 1

This can be achieved with the correct application of For loop and escaping of redirection characters.

@ECHO OFF
Call :find "connection strings.txt"
ECHO completed
pause
exit

:find

For /F "USEBACKQ delims=" %%a in ("%~1") DO (
    For %%i in (%%~a) DO (
    CALL :create "%%~i"
    )
) 2>nul
GOTO :EOF


:create
(
ECHO ^<Node Type="1"^>
ECHO ^<SavedSession^>%~1^</SavedSession^>
ECHO ^<DisplayName^>%~1^</DisplayName^>
ECHO ^<ServerName^>%~1^</ServerName^>
ECHO ^<PuttyConType^>0^</PuttyConType^>
ECHO ^<Port^>22^</Port^>
ECHO ^<UserName^>^</UserName^>
ECHO ^<Password^>^</Password^>
ECHO ^<PasswordDelay^>0^</PasswordDelay^>
ECHO ^<CLParams^>-load %~1 "%~1" -P 22^</CLParams^>
ECHO ^<ScriptDelay^>0^</ScriptDelay^>
)>>%~1.xml

GOTO :EOF