Puppet 中具有默认值的复杂结构

Question

Trying setup default values in an Array of Hashes in Puppet.
I am trying to configure urls to monitor.
It should contain:

• url
• name
• runbook
• comment[Optional]
• secure [default=true]
• warning [default=30]
• critical [default=15]

I got the following code:

puppet apply test.pp

test.pp:

class http_monitoring (
  Array[Struct[{
    url                 => String,
    name                => String,
    runbook             => String,
    Optional[comment]   => String,
    Optional[secure]    => Boolean,
    Optional[warning]   => Integer,
    Optional[critical]  => Integer,
  }]]
  $checks = [{
    secure   => true,
    warning  => 30,
    critical => 15,
  }]
){
  $checks.each | Hash $check | {
    notify {"${check}":}
  }
}

class website {
  class { 'http_monitoring':
    checks => [
      {url => 'https://example.com',  name => 'example'  ,runbook => 'https://link-to-docs.com/'},
      {url => 'https://example2.com', name => 'example2' ,runbook => 'https://link-to-docs.com/', warning => 5, critical => 10},
    ]
  }
}
include website

Results in:

Notice: {url => https://example.com, name => example, runbook => https://link-to-docs.com/}
Notice: /Stage[main]/Http_monitoring/Notify[{url => https://example.com, name => example, runbook => https://link-to-docs.com/}]/message: defined 'message' as '{url => https://example.com, name => example, runbook => https://link-to-docs.com/}'
Notice: {url => https://example2.com, name => example2, runbook => https://link-to-docs.com/, warning => 5, critical => 10}
Notice: /Stage[main]/Http_monitoring/Notify[{url => https://example2.com, name => example2, runbook => https://link-to-docs.com/, warning => 5, critical => 10}]/message: defined 'message' as '{url => https://example2.com, name => example2, runbook => https://link-to-docs.com/, warning => 5, critical => 10}'
Notice: Applied catalog in 0.01 seconds

The output I was hoping to get:

{url => 'https://example.com', name => example, runbook => https://link-to-docs.com/, secure => true, warning => 30, critical => 15}
{url => 'https://example2.com', name => 'example2', runbook => 'https://link-to-docs.com/', warning => 5, critical => 10, secure => true}

Running Puppet 6.12.0

Answer 1

Try this:

class http_monitoring (
  Array[Struct[{
    url                 => String,
    name                => String,
    runbook             => String,
    Optional[comment]   => String,
    Optional[secure]    => Boolean,
    Optional[warning]   => Integer,
    Optional[critical]  => Integer,
  }]]
  $checks = [{
    secure   => true,
    warning  => 30,
    critical => 15,
  }]
){
  $check_defaults = {
    secure   => true,
    warning  => 30,
    critical => 15,
  }

  # Checks with defaults
  $checks_with_defaults_added = $checks.map | Hash $next_check | {
    $check_defaults + $next_check
  }


  # $checks.each | Hash $check | {
  #   notify {"${check}":}
  # }

  $checks_with_defaults_added.each | Hash $check | {
    $check_output = String($check)
    notify { $check_output: }
  }
}

class website {
  class { 'http_monitoring':
    checks => [
      {url => 'https://example.com',  name => 'example'  ,runbook => 'https://link-to-docs.com/'},
      {url => 'https://example2.com', name => 'example2' ,runbook => 'https://link-to-docs.com/', warning => 5, critical => 10},
    ]
  }
}

include website