如何根据 SQL Server 中的另一列将一列值转换为两个不同的列值？

Question

I have a table A with columns B and C .

• Column B contains digit 2's and 4's.
• Column C contains respective numeric values for column B

For example:

table rows >>> (2,25),(4,6),(2,10),(4,54),(4,20),(2,30)

My requirement is, I need the result set with column names 2 and 4 and the respective values as rows.

I'd like the result set of rows to be:

>>> (25,6),(10,54),(30,20)

Answer 1

You need to have a way to order the records in an unique way, so you are sure which row with value 2 to which tow with value 4 to match.

In the example below I have added identity column to initially have a way to distinguish the rows and then use simply ROW_NUMBER to define how the rows are going to be combined.

Once, you have such column, the rest is simple JOIN :

DECLARE @DataSource TABLE
(   
    [row_id] INT IDENTITY(1,1)
   ,[value_one] INT
   ,[value_two] INT
);

INSERT INTO @DataSource ([value_one], [value_two])
VALUES (2,25)
      ,(4,6)
      ,(2,10)
      ,(4,54)
      ,(4,20)
      ,(2,30);

SELECT *
FROM
(
    SELECT ROW_NUMBER() OVER (ORDER BY [row_id]) AS [row_id]
          ,[value_one], [value_two]
    FROM @DataSource
    WHERE [value_one] = 2
) DS1
INNER JOIN
(
    SELECT ROW_NUMBER() OVER (ORDER BY [row_id]) AS [row_id]
          ,[value_one], [value_two]
    FROM @DataSource
    WHERE [value_one] = 4
) DS2
    ON DS1.[row_id] = DS2.[row_id];

Answer 2

If there can be any ordering of the rows , say if you have an additional column ID on which the rows can be ordered then the following may work - Use the [Lead] function (read more here ) to get the next value in the current row (assuming the first row starts with col B as 2, next row with col B as 4 and so on), then we can just get the alternate rows from the dataset.

DECLARE @A TABLE (ID INT IDENTITY(1,1), B INT, C INT)

INSERT INTO @A(B, C) VALUES (2,25)
INSERT INTO @A(B, C) VALUES (4,6)
INSERT INTO @A(B, C) VALUES (2,10)
INSERT INTO @A(B, C) VALUES (4,54)
INSERT INTO @A(B, C) VALUES (2,30)
INSERT INTO @A(B, C) VALUES (4,20)

;WITH [Data] AS (
SELECT *, C AS [2], LEAD(C) OVER (ORDER BY ID) AS [4]
FROM @A
)
SELECT d.[2], d.[4]
FROM Data d
WHERE d.Id %2 != 0

Outputs:

2  |4
-- |--
25 |6
10 |54
30 |20