我有如下 3 行的文件。 使用 linux 如何获取一行的拆分变量并将其附加到同一行

Question

Using linux, how can I get the below desired output for the given Input. Input file:

Line1: StringA1, stringB1| stringC1, stringD1, stringE1
Line2: StringA2, stringB2| stringC2, stringD2
Line3: StringA3, stringB3| stringC3, stringD3, stringE3, stringF3

My output should be:

StringA1, stringB1| stringC1
StringA1, stringB1| stringD1
StringA1, stringB1| stringE1
StringA2, stringB2| stringC2
StringA2, stringB2| stringD2
StringA3, stringB3| stringC3
StringA3, stringB3| stringD3
StringA3, stringB3| stringE3
StringA3, stringB3| stringF3

Answer 1

Assumptions:

• all lines have at least 3 fields
• the lines do not contain the string Line#: (otherwise we just need to modify the proposed script)

Sample data:

$ cat strings.dat
StringA1, stringB1| stringC1, stringD1, stringE1
StringA2, stringB2| stringC2, stringD2
StringA3, stringB3| stringC3, stringD3, stringE3, stringF3

One awk solution:

awk -F"[,|]" '
{ for ( i=3;i<=NF;i++ )
      { printf "%s,%s|%s\n", $1, $2, $i }
}' strings.dat

Where:

• -F"[,|]" - use comma and pipe ( ,| ) as input delimiters
• for ( i=3;i<=NF;i++ ) - for fields 3 to end of line (NF == number of fields == last field)
• { printf ... } - print 1st, 2nd and ith fields

Results of running the above:

StringA1, stringB1| stringC1
StringA1, stringB1| stringD1
StringA1, stringB1| stringE1
StringA2, stringB2| stringC2
StringA2, stringB2| stringD2
StringA3, stringB3| stringC3
StringA3, stringB3| stringD3
StringA3, stringB3| stringE3
StringA3, stringB3| stringF3

Answer 2

When you make a solution in sed , it will become hard to read and hard to maintain:

sed -E 's/,/\v/; :a; s/(.*\|)(.*),(.*)$/\1\2\r\1\3/;ta; s/\v/,/g;s/\r/\n/g' inputfile

Explanation:
s/,/\\v/ Most , should be replaced, but not the one in the replacement string.
:a Repeat next command (until ta ) while a replacement is found.
(.*\\|)(.*),(.*)$ Match 3 substrings: The starter, the middle part util the last , and the end part.
\\r Use the windows CR as a marker where we want a newline when finished.
\\1 Replace with the first remembered string (in example StringA1, stringB1 ).
/\\1\\2\\r\\1\\3/ Replace the last , with a newline marker and the starter.
ta; Repeat until all replacements are done.
s/\\v/,/g; Restore the , characters.
s/\\r/\\n/g' Replace new line marker with a real newline.

Other ways are using awk and a while loop . For a large file I recommand awk , perhaps you want to try this yourself before someone posts an answer.

Answer 3

In order to produce your desired output, if you are splitting on [,|] , you must further remove the beginning of field1 before outputting the results. There are two ways I see to do that. The first way simply splits field1 into an array with the fieldsep of ' ' , the second is with a combination of substr, match & length . The first is the simple way of doing it using the split() command, eg

awk -F '[,|]' '{
    split ($1, arr, / /)
    for (i=3; i<=NF; i++) {
        printf "%s,%s|%s\n", arr[2], $2, $i
    }
}' file

For the second, you can remove split() above and replace arr[2] with:

substr($1,match($1,/ /)+1,length($1)-match($1,/ /))

If your data file does not include "Line[0-9]: " as the prefix for each line, you can include the following as your printf to handle either case:

printf "%s,%s|%s\n", arr[2]=="" ? arr[1] : arr[2], $2, $i

The results are the same either way, but using split() would be the recommended way.

Example Use/Output

Using the proposed awk solution with your data file (named file adjust as needed), you can just select-copy/middle-mouse-paste in an xterm with the file in the current directory to obtain the results, eg

$ awk -F '[,|]' '{
>     split ($1, arr, / /)
>     for (i=3; i<=NF; i++) {
>         printf "%s,%s|%s\n", arr[2], $2, $i
>     }
> }' file
StringA1, stringB1| stringC1
StringA1, stringB1| stringD1
StringA1, stringB1| stringE1
StringA2, stringB2| stringC2
StringA2, stringB2| stringD2
StringA3, stringB3| stringC3
StringA3, stringB3| stringD3
StringA3, stringB3| stringE3
StringA3, stringB3| stringF3

Look things over and let me know if you have further questions.