根据列中的日期将行中的特定单元格复制到月工作表

Question

I want to copy specific columns in a row based on the date to sheets with the corresponding month attached. Like if column H in the Main sheet has Jan 15, 2020, I want that row to copy in the Jan-20 worksheet. And only specific columns from that row, just column c,d,g, and h to copy to the corresponding b,c,d, and f in the correct month sheet. I have searched and from what I am getting, to solve the specific cells in the row, I need an array. But I am confused about getting it to go to the different months (Jan-20-Dec-20).

Thank you for your time.

Answer 1

Construct the tab name from the date parts and use set ws = sheets(tab name) like this

Sub copyRows()

  Const COL_DATE As String = "H"
  Const ROW1 As Long = 2

  Dim mth
  mth = Array("", "Jan", "Feb", "Mar", "Apr", "May", "Jun", _
        "Jul", "Aug", "Sep", "Oct", "Nov", "Dec")

  Dim wb As Workbook, wsMain As Worksheet, ws As Worksheet
  Dim iLast As Long, iRow As Long, iTarget As Long
  Dim dDate As Date, sTab As String

  Set wb = ThisWorkbook
  Set wsMain = wb.Sheets("Sheet1")

  iLast = wsMain.Range(COL_DATE & Rows.Count).End(xlUp).Row

  For iRow = ROW1 To iLast

      dDate = wsMain.Range(COL_DATE & iRow).Value
      sTab = mth(Month(dDate)) & "-" & Format(dDate, "yy")

      Set ws = wb.Sheets(sTab)
      iTarget = 1 + ws.Range("F" & Rows.Count).End(xlUp).Row

      'c,d,g, and h to b,c,d, and f
      With wsMain
         .Cells(iRow, "C").Copy ws.Cells(iTarget, "B")
         .Cells(iRow, "D").Copy ws.Cells(iTarget, "C")
         .Cells(iRow, "G").Copy ws.Cells(iTarget, "D")
         .Cells(iRow, "H").Copy ws.Cells(iTarget, "F")
      End With

      Debug.Print dDate, sTab
  Next
End Sub