使用 Powershell/Batch 命令卸载 MS Office 更新（知识库文章）

Question

Is there a clean way to uninstall MS Word KB Article using Batch/ PowerShell command?

Background:

I've been trying to uninstall one KB Article (KB4475558) MS Word 2013. As a part of solution to manual team, who wants to uninstall all newly installed KB articles. I'm successful in trying to install multiple KB articles. But uninstalling has been quiet tricky.

So far tried,

Approach 1: wusa /uninstall /KB:4475558 wusa.exe /uninstall /kb:4475558 /norestart /quiet ---- It gives "This Action is Only Valid for Products That are Currently Installed" Error.

Approach 2 : Using GUID

Msiexec /I {90150000-006E-0401-1000-0000000FF1CE} MSIPATCHREMOVE={80BC2A33-0ADF-4731-AC75-046BA9B6B7AF} /qb ---- It gives "This Action is Only Valid for Products That are Currently Installed" Error.

Approach 3:

using Microsoft.Update.Searcher via link below,

PowerShell: How to find and uninstall a MS Office Update

-- Doesn't work.

Can you please help me on these questions:

1: I have manually installed those KB Articles, I'm able to uninstall it manually: But through scripts, it shows the above error. Why is it so?

2: Any other approach I might be missing?

Note : MS Office is not installed only MS word and Share point and there is no Trail version available in my machine. I also tried rebooting the machine once, but no avail.

Any help would be greatly helpful ! Thanks

Answer 1

Have you tried using a batch-file to parse the uninstall string from the registry uninstall key? I wouldn't usually recommend this method, but it may be better than nothing.

@(For /F "Delims=" %%G In (
    '^""%__AppDir__%reg.exe" Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /S /F "(KB4475558)" /D 2^>NUL^|Find "{"^"'
)Do @For /F "Tokens=2*" %%H In ('^""%__AppDir__%reg.exe" Query "%%G" /V "UninstallString" 2^>NUL^"')Do @Echo(%%I)&Pause

If you're satisfied with the results, you could modify the code to try uninstalling it, (it is likely that you'll need to run the script or command 'As administrator') :

From a batch-file :

@For /F "Delims=" %%G In (
    '^""%__AppDir__%reg.exe" Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /S /F "(KB4475558)" /D 2^>NUL^|Find "{"^"'
)Do @For /F "Tokens=2*" %%H In ('^""%__AppDir__%reg.exe" Query "%%G" /V "UninstallString" 2^>NUL^"')Do @%%I

or from cmd :

For /F "Delims=" %G In ('""%__AppDir__%reg.exe" Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /S /F "KB4475558" /D 2>NUL|Find "{""')Do @For /F "Tokens=2*" %H In ('""%__AppDir__%reg.exe" Query "%G" /V "UninstallString" 2>NUL"')Do @Echo(%I

---

If you were trying to do it for all KB updates for your office products, something like this may get you close:

@(For /F "Delims=" %%G In (
    '^""%__AppDir__%reg.exe" Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /S /F "0FF1CE}_Office" /K 2^>NUL^|Find "{"^"'
)Do @For /F "Tokens=2*" %%H In ('^""%__AppDir__%reg.exe" Query "%%G" /V "UninstallString" 2^>NUL^"')Do @Echo(%%I)&Pause

If you're satisfied with the results, you could modify the code to try uninstalling it, (it is likely that you'll need to run the script or command 'As administrator') :

From a batch-file :

@(For /F "Delims=" %%G In (
    '^""%__AppDir__%reg.exe" Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /S /F "0FF1CE}_Office" /K 2^>NUL^|Find "{"^"'
)Do @For /F "Tokens=2*" %%H In ('^""%__AppDir__%reg.exe" Query "%%G" /V "UninstallString" 2^>NUL^"')Do @Echo(%%I)&Pause

or from cmd :

For /F "Delims=" %G In ('""%__AppDir__%reg.exe" Query "HKLM\SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall" /S /F "0FF1CE}_Office" /K 2>NUL|Find "{""')Do @For /F "Tokens=2*" %H In ('""%__AppDir__%reg.exe" Query "%G" /V "UninstallString" 2>NUL"')Do @%I

---

Please note that the examples above are only parsing the registry key HKEY_LOCAL_MACHINE\\SOFTWARE\\Microsoft\\Windows\\CurrentVersion\\Uninstall . There may be other locations, such as HKEY_LOCAL_MACHINE\\SOFTWARE\\Wow6432Node\\Microsoft\\Windows\\CurrentVersion\\Uninstall holding information your require too.