在 Delphi 中使用 TRegEx 交换字符

Question

I need to swap character dot with comma and vice versa simultaneously.

function TformMain.SwapString(input, fromSymbol, toSymbol: String): String;
begin
  Result := AnsiReplaceStr(input, fromSymbol, '_');  //100,200_00
  Result := AnsiReplaceStr(Result, toSymbol, fromSymbol); //100.200_00
  Result := AnsiReplaceStr(Result, '_', toSymbol); //100.200,00
end;

How to do this using TRegEx in Delphi Rio?

Answer 1

Although this is not an answer to your question (how to do this using regular expressions), I'd like to point out that this task can be performed with much greater runtime performance using a simple loop:

function SwapPeriodComma(const S: string): string;
var
  i: Integer;
begin
  Result := S;
  for i := 1 to S.Length do
    case S[i] of
      '.':
        Result[i] := ',';
      ',':
        Result[i] := '.';
    end;
end;

This is much faster than both the AnsiReplaceStr approach and the regular expression approach.

Generalised to any two characters:

function SwapChars(const S: string; C1, C2: Char): string;
var
  i: Integer;
begin
  Result := S;
  for i := 1 to S.Length do
    if S[i] = C1 then
      Result[i] := C2
    else if S[i] = C2 then
      Result[i] := C1;
end;

(If you are OK with a procedure instead of a function, you can do this in-place and save memory and gain speed. But most likely you don't need such optimisations.)