Kusto 中的高级数据透视表

Question

I've just recently started using Kusto and so far so good. However, I've run into a roadblock which I'm having some issues in solving.

I have the following table

datatable(name:string, gender:string, occupation: string)
[
    "John", "Male", "Janitor",
    "Sam", "Male", "Pilot",
    "Mary", "Female", "CEO"
]

And I want to pivot it so I end up with a table like this

datatable(info:string, John:string, Sam: string, Mary: string)
[
    "Name", "John", "Sam", "Mary",
    "Gender", "Male", "Male", "Female",
    "Occupation", "Janitor", "Pilot", "CEO"
]
| where info != "Name"

The names in this case will always be unique, so that's not an issue.

Here is one of my pathetic attempts :)

datatable(name:string, gender:string, occupation: string)
[
    "John", "Male", "Janitor",
    "Sam", "Male", "Pilot",
    "Mary", "Female", "CEO"
]
| summarize d = make_bag(
    pack(
        name, pack_array(gender, occupation))
) by name
| evaluate  bag_unpack(d)

Answer 1

here's one option:

datatable(name:string, gender:string, occupation: string)
[
    "John", "Male", "Janitor",
    "Sam", "Male", "Pilot",
    "Mary", "Female", "CEO"
]
| as T
| summarize b = make_bag(pack(name, gender)) by info = "Gender"
| union (
    T
    | summarize b = make_bag(pack(name, occupation)) by info = "Occupation"
)
| evaluate bag_unpack(b)

Answer 2

This solution handles any number of columns:

let my_data = datatable(name:string, gender:string, occupation: string)
[
    "John", "Male", "Janitor",
    "Sam", "Male", "Pilot",
    "Mary", "Female", "CEO"
];
my_data
| getschema 
| project variable = ColumnName, type = ColumnType, i = ColumnOrdinal, Dummy = 1
| where variable != 'name'
| join kind = inner (my_data | project array = pack_array(*), Dummy = 1) on Dummy
| project name = tostring(array[0]), variable = variable, type, value = array[i]
| evaluate pivot(name, any(value))

All value columns are cast to 'dynamic' data type. To nevertheless retain the data type metadata, a 'type' column is added that holds the data type for any row in the output table.