查找动态范围的列和行 VBA 的最小值、最大值和平均值

Question

I am trying to find the MIN , MAX and AVERAGE of each column ( Note: number of columns varies each day). A summary table, on the next worksheet, of the MIN , MAX and AVERAGE of each column is the desired output. Each of the columns has a unique serial number (As per summary information in photo below).

Also, I am trying to find the MIN , MAX and AVERAGE of each row ( Note: number of rows also varies each day). These values are desired to be listed in Columns CZ (min), DA (Max), DB(Average).

Please find my attempt below, which gave the following error:

"Run-time error '1004': Unable to get the Min property of the WorksheetFunction class"

I have attempted this with formulas but the excel sheet slows down dramatically, so was hoping VBA would speed the processing up. I would have estimated 2000-4000 rows and up to 100 columns of temperature data.

Sub Range_End_Method()
'Finds the last non-blank cell in a single row or column

Dim Row As Long
Dim Col As Long
Dim MinValue As Integer
Dim Min_Values As Range
Dim Cycle As Integer
Dim RangeNew As Variant

    'Find the last non-blank cell in column C(1)
    Row = ThisWorkbook.Sheets("1. Paste Raw Data").Cells(Rows.Count, 3).End(xlUp).Row

    'Find the last non-blank cell in row 9
    Col = ThisWorkbook.Sheets("1. Paste Raw Data").Cells(9, Columns.Count).End(xlToLeft).Column

For i = 3 To Col

    RangeNew = Range(Cells(9, i).Address, Cells(Row, i).Address).Address
    MinValue = Application.WorksheetFunction.Min(RangeNew)
    Cycle = 3
    MinValue = Sheets("5. Summary Information").Cells((Cycle + i), i)

    Next

End Sub

Answer 1

I don't think the code below will do what you want but it features correct syntax for setting a range and for determining the last used row and column in a worksheet. Given the correct syntax you may now be able to introduce the correct logic.

Sub Range_End_Method()
    ' Variatus@STO 22 Feb 2020

    Dim MinValue As Integer
    Dim MinRng As Range
    Dim Cycle As Integer
    Dim Rl As Long                      ' last used row
    Dim Cl As Long                      ' last used column
    Dim i As Integer

    'Find the last non-blank cell in column C(1)
    ' rows and columns must be counted in the same sheet!
    With ThisWorkbook.Sheets("1. Paste Raw Data")
        Rl = .Cells(.Rows.Count, 3).End(xlUp).Row

        'Find the last non-blank cell in row 9
        Cl = .Cells(9, .Columns.Count).End(xlToLeft).Column

        Cycle = 3
        For i = 3 To Cl
            Set MinRng = .Range(.Cells(9, i), .Cells(Rl, i))
            Debug.Print MinRng.Address
            MinValue = Application.WorksheetFunction.Min(MinRng)
            Sheets("5. Summary Information").Cells((i + Cycle), i).Value = MinValue
        Next i
    End With
End Sub

I draw your attention to the line Debug.Print MinRng.Address which I have added to support your testing. This line will print the address of the MinRange to the Immediate window on each iteration and you can see if it is what you intend.

Note also that I have reversed your code for writing the MinValue to sheet 5. It appeared more logical to me this way but I doubt that the coordinates of the target cell are specified correctly.