将动态范围数据从垂直格式转换为水平格式

Question

This is the data given to me, you can see the columns B and C are similar in all aspects except the Export items data:

This is the data which is transposed to horizontal way without VBA code:

Only issue is whenever i try doing it via VBA code, i don't get the remaining data as it is. it comes in as jumbled.

  Sub test2()
    Dim Ws As Worksheet
    Dim toWs As Worksheet
    Dim vDB, vR()
    Dim rngDB As Range
    Dim i As Long, j As Long, n As Long
    Dim r As Long, c As Long, k As Long

    Set Ws = Sheets(1)
    Set toWs = Sheets(2)

    Set rngDB = Ws.Range("a1").CurrentRegion
    vDB = rngDB

    r = UBound(vDB, 1)
    c = UBound(vDB, 2)

    For j = 2 To c
        n = n + 1
        'ReDim Preserve vR(1 To 4, 1 To n)
        ReDim Preserve vR(1 To 5, 1 To n)
        vR(1, n) = vDB(1, j)
        vR(2, n) = vDB(2, j)
        vR(3, n) = vDB(3, j)
        vR(4, n) = vDB(4, j)
        vR(5, n) = vDB(r, j) 'added insurance
        'For i = 5 To r
        For i = 5 To r - 1
            If vDB(i, j) <> "" Then
                n = n + 1
                ReDim Preserve vR(1 To 5, 1 To n)
                vR(4, n) = vDB(i, j)
            End If
        Next i
    Next j

    With toWs
        k = .UsedRange.Rows.Count + 1
        '.Range("a" & k).Resize(n, 4) = WorksheetFunction.Transpose(vR)
        .Range("a" & k).Resize(n, 5) = WorksheetFunction.Transpose(vR)
    End With

End Sub

Answer 1

Try this:

Sub Test2()

    Dim i&, j&, vIn, vOut

    With ThisWorkbook

        vIn = .Worksheets(1).Range("a1").CurrentRegion.Value2

        ReDim vOut(1 To UBound(vIn, 2), 1 To UBound(vIn, 1))

        For i = 1 To UBound(vIn, 1)
            For j = 1 To UBound(vIn, 2)
                vOut(j, i) = vIn(i, j)
            Next
        Next

        .Worksheets(2).Range("a1").Resize(UBound(vOut, 1), UBound(vOut, 2)) = vOut

    End With    

End Sub

A more generic, reusable, and functional way to do it would be like so...

Sub Test3()

    Dim vIn

    With ThisWorkbook        
        vIn = .Worksheets(1).[a1].CurrentRegion.Value2
        .Worksheets(2).[a1].Resize(UBound(vIn, 2), UBound(vIn, 1)) = MyTranspose(vIn)            
    End With

End Sub

Function MyTranspose(vIn)

    Dim i&, j&, vOut

    ReDim vOut(1 To UBound(vIn, 2), 1 To UBound(vIn, 1))        
    For i = 1 To UBound(vIn, 1)
        For j = 1 To UBound(vIn, 2)
            vOut(j, i) = vIn(i, j)
        Next
    Next    
    MyTranspose = vOut

End Function

Answer 2

Transpose data

tltr; and I didn't follow the prior discussion ... but why not just apply Application.Transpose() to the entire data set instead of executing inner and outer loops?

Option Explicit                                               ' declaration head of code module

Sub TransposeData()
    '[1]get data and assign them to variant 1-based 2-dim array
        Dim v ' As Variant
        v = Sheet1.Range("A1").CurrentRegion.Value2            ' << change to your source worksheet's CodeName

    '[2]transpose data and write to target sheet - e.g. Code(Name) Sheet2  
        Sheet2.Range("A1").Resize(UBound(v, 2), UBound(v, 1)) = Application.Transpose(v)

End Sub