如何转换具有层次结构的表？

Question

I have a table with two columns which looks like this

I want to bring it to this format wherein all the User IDs under a manager's hierarchy are mapped which should like this. If a user id does not have a manager id, then the same user id needs to be used as manager id

Any help or even if I am pointed in the right direction will be extremely helpful. Thank you

Answer 1

It is just a classic case of recursion on a hierarchy:

declare @table table (ManagerId int, userId int);
insert @table values 
    (4,1), (4,2), (4,3), -- report to 4
    (5,4), -- report to 5
    (6,5), -- report to 6
    (7,6); -- report to 7

with traverse as (

    select     managerId, userId
    from       @table t

    -- Union all in a cte selecting from 
    -- the cte itself initiates recursion.
    union all  
    select     nxt.managerId, cur.userId
    from       traverse cur
    join       @table nxt on cur.managerId = nxt.userId 
    where      nxt.managerId is not null
)


select     isnull(managerId, userId) managerId, userId
from       traverse             
order by   managerId, userId
option     (maxrecursion 1000) -- change if you're getting a max recursion error

Answer 2

I see there has been a lot of progress while I was working on a solution for you. It may not have adapted to the latest changes. Please take a look.

Option Explicit

Enum Nws                        ' worksheet locations
    NwsFirstDataRow = 2
    NwsStaff = 1                ' 1 = column A
    NwsSuper                    ' no value = (preceding + 1)
                                ' the above columns need not be adjecent
    NwsManager = 5              ' { blank columns for output
    NwsUserID                   ' { function as your sample
End Enum

Sub SortHierarchy()
    ' Variatus @STO 12 Mar 2020

    Dim Rng As Range
    Dim Arr As Variant
    Dim i As Long                           ' index to Arr()
    Dim StaffID As Variant                  ' can be alphanumeric
    Dim Rl As Long                          ' last row
    Dim R As Long                           ' current row
    Dim Spike() As String
    Dim n As Long                           ' index to Spike()
    Dim Sp() As String                      ' split of Spike(n)


    Application.ScreenUpdating = False

    With Worksheets("Sheet1")               ' modify tab name
        Rl = .Cells(.Rows.Count, NwsStaff).End(xlUp).Row
        ' both columns should be of equal length
        Set Rng = .Range(.Cells(NwsFirstDataRow, NwsStaff), _
                         .Cells(Rl, NwsSuper))
        SortData Rng, NwsSuper
        Arr = Rng.Columns(NwsSuper).Value
        ReDim Spike(UBound(Arr) - 1)

        For R = NwsFirstDataRow To Rl
            StaffID = .Cells(R, NwsStaff).Value
            n = R - NwsFirstDataRow
            Spike(n) = StaffID
            For i = 1 To UBound(Arr)
                If Arr(i, 1) >= StaffID Then
                    Spike(n) = Spike(n) & "," & .Cells(i + 1, NwsStaff).Value
                End If
            Next i
        Next R

        .Columns(NwsManager).Resize(, 2).ClearContents
        .Cells(1, NwsManager).Value = "Manager"
        .Cells(1, NwsUserID).Value = "UserID"
        R = NwsFirstDataRow

        For n = 0 To UBound(Spike)
            Sp = Split(Spike(n), ",")

            For i = 0 To UBound(Sp)
                If Len(Sp(i)) = 0 Then Exit For

                If Sp(i) <> Sp(0) Then
                    .Cells(R, NwsManager).Value = Sp(0)
                    .Cells(R, NwsUserID).Value = Sp(i)
                    R = R + 1
                End If
            Next i
        Next n

        Rl = .Cells(.Rows.Count, NwsManager).End(xlUp).Row
        Set Rng = .Range(.Cells(NwsFirstDataRow, NwsManager), _
                         .Cells(Rl, NwsUserID))
    End With
    SortData Rng

    Application.ScreenUpdating = True
End Sub

Private Sub SortData(Rng As Range, _
                     Optional ByVal SortColumn As Nws)

    With Rng.Worksheet.Sort
        With .SortFields
            .Clear
            If (SortColumn = NwsStaff) Or (SortColumn = 0) Then
                .Add Key:=Rng.Columns(NwsStaff), SortOn:=xlSortOnValues, _
                     Order:=xlAscending, DataOption:=xlSortNormal
            End If
            If (SortColumn = NwsSuper) Or (SortColumn = 0) Then
                .Add Key:=Rng.Columns(NwsSuper), SortOn:=xlSortOnValues, _
                     Order:=xlAscending, DataOption:=xlSortNormal
            End If
        End With
        .SetRange Rng
        .Header = xlNo
        .MatchCase = False
        .Orientation = xlTopToBottom
        .SortMethod = xlPinYin
        .Apply
    End With
End Sub

This code will run on a worksheet called "Sheet1" (amend in procedure SortHierarchy ) and requires data in columns A and B (amend in the Enum at the top of the code. Run the procedure SortHierarchy .

My data in columns A and B might differ from yours. For my own clarity I called the columns "StaffID" and "ReportsTo". In principle every staff member reports to somebody. Therefore column A may hold a list of all staff members. The applied logic is that if the worker reports to the supervisor, the supervisor to the manager and the manager to the boss, then worker, supervisor and manager all report to the boss. The boss reports to nobody which is to say himself. The same status can be allocated to any staff member. It's also possible to let a worker report directly to the boss. All of this is expressed in the two columns "StaffID" and 'ReportsTo".

The macro takes these data and sorts them into a hierarchical list which is written to two blank columns on the same worksheet. You can assign the columns in the Enum. Note that the macro will allow for data between the columns A and B (which are freely assignable) and those data would stay aligned with the data being sorted.